[Padlowan]

Made some sprites of the Ratoid from Manhattan Project a while ago.


ZIP

.ART File

I considered making these 8-sided (because of the bag at the side) but 5 seems to look okay in game.

[ck3D]

That is a great idea and super well executed!

[Paul B]

MObreck, on 30 April 2022 - 12:02 AM, said:

I went ahead and uploaded my Wolfenstein conversion mod I made back in the 90s. It only has a few stages (That are noticeable modded conversions of DOOM stages) so that's why I consider it a resource kit rather than a fully functional TC. But it does have around 40 custom enemies and large selection of textures, so a rather massive resource kit:

https://www.nexusmod...nukem3d/mods/2/

I won't personally be expanding on this, but if anyone else wants to use it as a starting point to develop a more refined Wolfenstein mod go right ahead. It was built with vanilla Atomic Edition (EDuke didn't even exist when I made it). But I tweaked it to run on modern EDuke (You'll a bunch of warnings in the bootup log though).

Some Preview Screens:

This is one of the coolest mods i've seen for Duke.

[VGames]

Has anybody ever made a death animation for the liztroop where they fall on their back on not on their stomach?

[MajorTom 2417]

Padlowan, on 19 July 2025 - 03:15 AM, said:

Made some sprites of the Ratoid from Manhattan Project a while ago.


ZIP

.ART File

I considered making these 8-sided (because of the bag at the side) but 5 seems to look okay in game.

Now this is just BOSS.

Any chance you can convert other Manhattan Project enemies to sprite form?

[Padlowan]

MajorTom 2417, on 31 August 2025 - 12:43 PM, said:

Now this is just BOSS.

Any chance you can convert other Manhattan Project enemies to sprite form?

There's a good chance I will!
The one I've been thinking of converting in the foreseeable future is the Roachoid.

[MajorTom 2417]

Padlowan, on 02 September 2025 - 09:42 AM, said:

There's a good chance I will!
The one I've been thinking of converting in the foreseeable future is the Roachoid.

noice

Seeing as how there are very few, if any, robotic enemies in DN3D mods, the camera drone, the bipedal mech and, yes, the Fem-Mech would all be interesting choices to get converted to sprite form as well. But the Roachoid is a good next step.

[Padlowan]

Manhattan Project Roachoid Sprites:


ZIP

.ART

[Reaper_Man]

I am currently going through some AWOL code and want to share a few things that could easily be used by other mods, TCs, and games.

The first is this gunfire and explosion distance sounds. This effect will overlay and "fade out" gunshot sounds with distant gunfire sounds. See these 2 videos for some (old, still WIP era) videos demoing the effect.

https://www.msleeper...04_10-24-33.mp4

https://www.msleeper...20_09-43-22.mp4

(The second one is using procedural gunfire sound emitters, used in the Dubai level to make it sound like distant firefights were happening. The first is a better real-world example.)

The effect is pretty straight forward and mostly relies on having the sound assets for the far away gunfire. As well as the distance setting of the sounds set in an overlapping manner. We use soundvar for most of this. It becomes easier if your sound definitions are sequentially numbered:

define MP5_FIRE1                        251
define MP5_FIRE2                        252
definesound MP5_FIRE1                    sounds/weapons/mp5/mp5_fire.ogg        -128    -64        253        0        0
definesound MP5_FIRE2                    sounds/weapons/mp5/mp5_fire.ogg        -128    -64        253        0        0

define MP5_FIRE1_FAR                    762
define MP5_FIRE2_FAR                    763
definesound MP5_FIRE1_FAR                sounds/weapons/mp5/mp5_fire_far.ogg            -512 0 128 0 -32768
definesound MP5_FIRE2_FAR                sounds/weapons/mp5/mp5_fire_far.ogg            -512 0 128 0 -32768

Notice the distance for the "far away" sounds, this effectively doubles the "range" of the sound.

When an actor needs to play a gunfire sound, call this state instead of playing the sound directly. This saves these 2 sound IDs for future use:

defstate enemy_shootmp5
{
    // Play alternating sounds so we don't overwhelm the sound system
    set ACTORTEMP MP5_FIRE1
    set ACTORTEMP2 MP5_FIRE1_FAR
    state actor_shoot_sound
}
ends

Then we either override the gunfire sound with the far way sound, or we play both of them.

defstate actor_shoot_sound
{
    ifpdistg GUNSHOT_DIST_FAR
        set ACTORTEMP ACTORTEMP2
    else
    ifpdistg GUNSHOT_DIST_CLOSE
    {
        add ACTORTEMP2 ACTORSOUNDCYC
        soundvar ACTORTEMP2
    }

    soundvar ACTORTEMP
    xor ACTORSOUNDCYC 1
}
ends

The "xor ACTORSOUNDCYC 1" trick is used to prevent from overwhelming the sound engine. A specific sound ID cannot be played multiple times, and if you try to then the sound engine will stop the first playback. So we have each gunfire sound defined twice using the same source sound. This allows rapid fire gunshots to sound more natural and the audio cutoff less obvious. This is why having your sound IDs be sequential helps as mentioned before, you could do this with non-sequential sound IDs but it would be messy code.

Last, we also capture and remap the gunfire sound directly in EVENT_SOUND. This is necessary as it handles gunfire sounds from non-enemies or non-actors not running the above code. This code does not allow the playback of both normal and distance sounds, this only converts the out of range ones. You may be able to get away with only using this without the "ifpdistg GUNSHOT_DIST_FAR" block above, but I recall having some issues with that so I'm sure there's a reason I implemented both.

// Distance where actors will play both sounds (in enemy_shared.con) to prevent hard cutover
define GUNSHOT_DIST_CLOSE 16384

// Distance where all gunshots will cut over to distant ones
define GUNSHOT_DIST_FAR 20384

// Captures a given gun fire sound and remaps it based on distance from the source
appendevent EVENT_SOUND
{
    switch RETURN
    {
        case MP5_FIRE1
        case MP5_FIRE2
            // Failsafe to return original sound
            set ACTORTEMP RETURN

            ldist ACTORCHECK THISACTOR player[].i
            ifg ACTORCHECK GUNSHOT_DIST_FAR
            {
                switch RETURN
                {
                    case MP5_FIRE1
                        set ACTORTEMP MP5_FIRE1_FAR
                        break
                    case MP5_FIRE2
                        set ACTORTEMP MP5_FIRE2_FAR
                        break
                    default
                        set ACTORTEMP SPAS12_FIRE2_FAR
                        break
                }
                endswitch
            }

            // Return new sound
            set RETURN ACTORTEMP

            break
    }
    endswitch
}
endevent

We do something very similar for explosion sounds, but again the effect really depends on having the right assets to pull it off. This code block has a lot more special exceptions, most for gameplay experience reasons.

/*
// Dynamic explosion sound handling
*/

define EXPLOSION_DIST_MED 8192
define EXPLOSION_DIST_FAR 16384

// Captures a given explosion sound and remaps it based on distance from the source
appendevent EVENT_SOUND
{
    switch RETURN
    {
        case RPG7_ROCKETEXPLO
        case GREN_EXPLO
        case EXPLOSION01
        case PIPEBOMB_EXPLODE
        case RPG_EXPLODE
        case LASERTRIP_EXPLODE
            dist ACTORCHECK THISACTOR player[].i

            // Play tinnitus sound for nearby explosions (but not during startup animation)
            ifl ACTORCHECK 2048
                ifand player[].gm 4
                    screensound EXPLOSION_TINNITUS

            rand ACTORTEMP 3
            add ACTORTEMP EXPLOSION_NEAR1

            ifg ACTORCHECK EXPLOSION_DIST_MED
                add ACTORTEMP 4
            ifg ACTORCHECK EXPLOSION_DIST_FAR
                add ACTORTEMP 4

            // Do not use dynamic near or medium sounds for weapon explosions
            ifl ACTORTEMP EXPLOSION_FAR1
            {
                ife RETURN RPG7_ROCKETEXPLO
                    set ACTORTEMP RETURN
                else
                ife RETURN GREN_EXPLO
                    set ACTORTEMP RETURN
            }

            // Handle the hardcoded PIPEBOMB_EXPLODE in the intro animation
            ife RETURN PIPEBOMB_EXPLODE
            {
                ifand player[].gm 4
                    nullop
                else
                    set ACTORTEMP -1
            }

            // Return new sound
            set RETURN ACTORTEMP

            break
    }
    endswitch
}
endevent