[NightFright]

I'm trying to code a replacement for the mini HUD (screensize 4, no EDuke32 HUD). Two issues remain:

1) [UNSOLVED] At the moment it is not affected by the statusbarscale variable, i.e. it always remains at 100% size.

It starts like this:

onevent EVENT_DISPLAYSBAR
    ifvare userdef[].screen_size 4 
        ifvare userdef[].althud 0
        {
	    // Remove default HUD
            set RETURN -1

            [...]
        }
endevent

Which modifications would be required to make scaling work?

------------------------------------------

2) [SOLVED] The calculation for the inventory item percentage is somewhat off compared to the original, most likely due to rounding inaccuracies when dividing the inventory amount value.

Example (Steroids):

getp[].steroids_amount INVPCT 
div INVPCT 4
digitalnumber THREEBYFIVE 98 190 INVPCT 0 0 272 0 0 xdim ydim

If done like this, the modded display would always be slightly lagging behind the original one. Is there any way to make the conversion more accurate? (In the end it's just a display issue since the original, unconverted value remains the same, it's just about the percentage not matching vanilla.)

[Danukem]

NightFright, on 19 March 2024 - 01:31 AM, said:

Example (Steroids):

getp[].steroids_amount INVPCT 
div INVPCT 4
digitalnumber THREEBYFIVE 98 190 INVPCT 0 0 272 0 0 xdim ydim

If done like this, the modded display would always be slightly lagging behind the original one. Is there any way to make the conversion more accurate? (In the end it's just a display issue since the original, unconverted value remains the same, it's just about the percentage not matching vanilla.)

Can't you just add 1 if the number is odd?

getp[].steroids_amount INVPCT 
div INVPCT 4, ifvarand INVPCT 1 add INVPCT 1
digitalnumber THREEBYFIVE 98 190 INVPCT 0 0 272 0 0 xdim ydim

[NightFright]

That will rather skip every odd value and just print even numbers (mostly), i.e. 98, 96 etc.

*UPDATE*
Found the solution. Instead of "div" (which is "divrd", i.e. round down) I have to use "divr" (0.5 equals 1).
So that only leaves the statusbar scaling issue.

[NightFright]

Here is the full statusbar code. Maybe it will help to figure out how to implement scaling functionality. It's the only thing I'm missing.

Spoiler

// "Armor" display for World Tour Mini HUD

// Variables
var HUDSTAT 0 2
var INVPCNT 0 2

// Inventory: Quote for labels and percentage display
definequote 999 DUMMY

// Inventory: Percentage display
defstate drawpercent
    redefinequote 999 %d
    qsprintf 999 999 INVPCNT
    screentext THREEBYFIVE 134 194 65536 0 0 999 0 0 256 0 4 8 1 0 524289 0 0 xdim ydim
    rotatesprite 136 192 65536 0 3076 0 6 256 0 0 xdim ydim
ends

// Inventory: "OFF" label
defstate label_off
    redefinequote 999 OFF
    screentext MINIFONT 139 182 65536 0 0 999 0 2 256 0 4 8 1 0 1 0 0 xdim ydim
ends

// Inventory: "ON" label
defstate label_on
    redefinequote 999 ON
    screentext MINIFONT 139 182 65536 0 0 999 0 0 256 0 4 8 1 0 1 0 0 xdim ydim
ends

// Inventory: "AUTO" label (x+1)
defstate label_auto
    redefinequote 999 AUTO
    screentext MINIFONT 139 182 65536 0 0 999 0 2 256 0 4 8 1 0 1 0 0 xdim ydim
ends

// Redraw mini HUD
onevent EVENT_DISPLAYSBAR
    ife userdef[].screen_size 4 
        ife userdef[].althud 0
        {
            // Remove default HUD
            set RETURN -1

            // Health
            rotatesprite 20 185 65536 0 30 0 0 256 0 0 xdim ydim
            geta[].extra HUDSTAT
            digitalnumber DIGITALNUM 20 183 HUDSTAT 0 0 272 0 0 xdim ydim

            // Armor
            rotatesprite 52 185 65536 0 5171 0 0 256 0 0 xdim ydim
            getp[].shield_amount HUDSTAT
            digitalnumber DIGITALNUM 52 183 HUDSTAT 0 0 272 0 0 xdim ydim

            // Ammo
            rotatesprite 84 185 65536 0 31 0 0 256 0 0 xdim ydim
            getp[].curr_weapon HUDSTAT
            getp[].ammo_amount HUDSTAT HUDSTAT
            digitalnumber DIGITALNUM 84 183 HUDSTAT 0 0 272 0 0 xdim ydim

            // Inventory
            ifn player[].inven_icon 0
                rotatesprite 122 184 65536 0 33 0 0 256 0 0 xdim ydim
            switch player[].inven_icon
                case 1
		    rotatesprite 113 186 65536 0 2460 0 0 256 0 0 xdim ydim   // x+1, y+1
		    getp[].firstaid_amount INVPCNT
                    state drawpercent
                break
                case 2
		    rotatesprite 113 186 65536 0 2469 0 0 256 0 0 xdim ydim   // x+3
		    getp[].steroids_amount INVPCNT
		    divr INVPCNT 4
                    state drawpercent
                break
                case 3
		    rotatesprite 113 186 65536 0 2470 0 0 256 0 0 xdim ydim   // x+4, y-2
		    getp[].holoduke_amount INVPCNT
		    divr INVPCNT 24
                    state drawpercent
                    ife player[].holoduke_on -1
                        state label_off
                    else
                        state label_on
                break
                case 4
		    rotatesprite 113 186 65536 0 2467 0 0 256 0 0 xdim ydim   // x+2
	            getp[].jetpack_amount INVPCNT
	            divr INVPCNT 16
                    state drawpercent
                    ife player[].jetpack_on 0
                        state label_off
                    else
                        state label_on		
                break
                case 5
		    rotatesprite 113 185 65536 0 2461 0 0 256 0 0 xdim ydim   // x+1
		    getp[].heat_amount INVPCNT
		    divr INVPCNT 12
                    state drawpercent
                    ife player[].heat_on 0
                        state label_off
                    else
                        state label_on
                break
                case 6
		    rotatesprite 113 186 65536 0 2468 0 0 256 0 0 xdim ydim   // x+1, y-1
		    getp[].scuba_amount INVPCNT
		    divr INVPCNT 64
                    state drawpercent
                    state label_auto
                break
                case 7
		    rotatesprite 112 187 65536 0 2463 0 0 256 0 0 xdim ydim   // y+1
		    getp[].boot_amount INVPCNT
		    divr INVPCNT 2
                    state drawpercent
                    state label_auto
                break
            endswitch
        }	
endevent