[High Treason]

Hey, I just about got NBCBP V2 finished and ready for release, but one thing is holding me back. I have a switch, but when I press it, it does not stop flickering on and off, here is the code with several experimental things left in;

// Stupid-ass dipswitch
define NCBPBUTTON1 3590
 useractor notenemy NCBPBUTTON1 0
  ifactioncount 1 break else
	ifpdistl 800 ifhitspace
	  {
		setvarvar currlev LEVEL
		action CBPRESS
		ifactioncount 1 action ANULLACTION
		
		  ifvare currlev 1
			setvar NCBP1 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 2
			setvar NCBP2 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 3
			setvar NCBP3 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 4
			setvar NCBP4 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 5
			setvar NCBP5 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 6
			setvar NCBP6 1
			  soundonce SWITCH_ON
			   quote 150
//		  else
		  ifvare currlev 7
			setvar NCBP7 1
			  soundonce SWITCH_ON
//		  else
		  ifvare currlev 8
			setvar NCBP8 1
			  soundonce SWITCH_ON
//		  else
			break
	  }
enda

[Danukem]

There are several problems with that code. But first: Do you want this switch to only work once and then never be usable again?

[High Treason]

Well, that's it's intention, but I never bothered with that too much before as I didn't put an action in in the previous revision... Talking of the Action, that is defined;

action CBPRESS 0 2 1 1 1

There probably are numerous problems with the code, infact the ammount of comments probably show just how poor my coding is.

[Danukem]

The switch can only be in 2 positions, right? One for the off position and one for the on position. Assuming that it starts in the off position (which would be equivalent to ANULLACTION) then your CBPRESS action should only have 1 frame (the on position frame). But yours has 2 frames.

I'm not trying to help fix your code yet, I'm just trying to understand what is going on with the animation because I can't see the art file or whatever you are using for the graphics.

[High Treason]

Correct, and it did have 1 frame before, but it did the exact same thing, can't remember why I changed it. It starts in the off position and is then switched on by the player hitting space near it (I know there are a bunch of things like ifpfacing that should be there - but I can't be bothered implementing it).

There are actually 8 duplicates defined from how it was originally intended to be coded before I integrated it in one actor (the switch).

So yeah, switch can only be on or off. When I only had "action CBPRESS" in the code, it did the same thing and just flickered on and off.

[Danukem]

OK, I'm going to assume that this action will show the switch in the OFF position:

action CBPRESS 1 1 1 1 1

If not, then it's your fault and you need to change the art or whatever. With that in mind, here is some code that should work:

define NCBPBUTTON1 3590

 useractor notenemy NCBPBUTTON1 0

ifaction CBPRESS break

ifp pfacing // this is not perfect but it's good enough for now
  ifpdistl 800
	ifhitspace
	  ifcanseetarget
	{
		action CBPRESS
		sound SWITCH_ON
		quote 150
		
		  ifvare LEVEL 1
			setvar NCBP1 1
		  else
		  ifvare LEVEL 2
			setvar NCBP2 1
		  else
		  ifvare LEVEL 3
			setvar NCBP3 1
		  else
		  ifvare LEVEL 4
			setvar NCBP4 1
		  else
		  ifvare LEVEL 5
			setvar NCBP5 1
		  else
		  ifvare LEVEL 6
			setvar NCBP6 1
		  else
		  ifvare LEVEL 7
			setvar NCBP7 1
		  else
		  ifvare currlev 8
			setvar NCBP8 1
	}
enda

Note that this code still looks kind of odd. Why do you have a different variable for each level? I'm sure you can get by with only one variable. Also, note that LEVEL equals 0 in the first level of an episode, and you have the switch doing nothing in the case. I'm not sure if that's what you intended.

[High Treason]

Thanks. Now to explain a little;

The switch updates the HUD depending on what level you are on (there are 8 dots at the top, one to symbolise each level) and also causes a panel to dissapear in the hub map (LEVEL 0 - there is no switch in the hub map).

The code functions, but the switch does not change tile (the tile with the ON position) when I press it. It's probably my fault and I'm half inclined to leave it.

[Danukem]

High Treason, on Mar 10 2011, 02:22 PM, said:

The code functions, but the switch does not change tile (the tile with the ON position) when I press it. It's probably my fault and I'm half inclined to leave it.

Make tile 3590 the switch in one position and tile 3591 the switch in the other position (whatever order you want). That's all there is to it. Why would you leave it when it is so easy to fix?

You can easily get rid of those variables and just have one variable that is used as a bit field, but that's a story for another time.

[High Treason]

That's how things are in the art (It used .def files for the art) - but it still doesn't cause the switch to change. Here's how the art files look;


There are eight of those panels, one more dissapears in the hub map for every level you hit the switch in - this part works. Do I need to set up the "On" tile in the .con in some way? I'm willing to bet I've gone and overlooked something stupid. As for bitfields, yeah, that is for another time, I've never used them yet, to be honest, with the one-time-use of the switch, I could get it working using addvar, but then I would have to change code in other places for something that would likely be un-noticed in the game.

[Danukem]

Sorry, the action should be:

action CBPRESS 1 1 1 1 1

I don't know how I managed to miss that.

[High Treason]

Ah, that's done it! Thanks for all of your help, the switch now works perfectly.

You have been added to the credits list for the project, if you want removing from it for some reason, let me know and I'll remove it.

[Danukem]

I'm inclined to ask you to remove it simply because I am already credited for so many different projects that it seems silly. Besides, I didn't do much. The only reason to credit me would be if you were using something much more substantial, like big chunks of code from one of my mods.

[High Treason]

Ok, if that's what you want, consider it done - your name has now been removed from the list. The reason I added it is because I do like to credit anybody that helps, regardless of what it was they did, back when animation was my thing I used to have all kinds of stupid things in the credits, even the guy at Kwik Save that found more pot noodles for me whilst I was working on something - actually, maybe I do take crediting a bit too far.

[wayskobfssae]

Im simply trying to hide the default weapon tiles to input my own.

onevent EVENT_DISPLAYWEAPON
{
getplayer[THISACTOR].curr_weapon temp
ifvare temp PISTOL_WEAPON
{
setvar RETURN -1
}
}
endevent

But... I get no change. I've tried using both PISTOL_WEAPON and 1 as the value for RETURN. And I've tried both displayweapon and drawweapon as the event.

[Danukem]

onevent EVENT_DISPLAYWEAPON

ifvare currentweapon 1 setvar RETURN -1

endevent

[wayskobfssae]

Gracias.

[wayskobfssae]

It's probably simpler if I just write this in pseudo... what I'm trying to do is mimic a 'planar' explosion. Like the blast ring produced by the shock rifle in unreal. Whereas, when the weapon hits a surface, the blast ring is oriented to the angle of that surface. What I have in mind now is:


if I'm near the floor then
{
be a floor-aligned sprite
}
else
{
be a normal aligned sprite
if I'm near a wall then be a wall aligned sprite and set my angle to the wall's angle
}


Getting the floor aligned part to work is easy. But I don't see a way to make an actor check for walls in this way. I was sort of hoping that perhaps the projectile passes information on what it hit to the sprite that it spawns on impact, but maybe this is just wishful thinking. And since the explosion is meant to remain stationary, I can't use htmovflag to test for walls.

[Danukem]

You should be able to check the htmovflag of the projectile in EVENT_KILLIT to determine the wall it is hitting, if any. You can then calculate the wall angle by comparing the x and y coords of the wall point with the x and y of the the other wall point (the other wall point ID is in the point2 member of the wall struct), just as you would calculate the angle to make one actor face another. Make the projectile spawn the explosion using espawn, and then set the angle and whatever else you need to set on the explosion sprite(s). Define the projectile so it spawns nothing by default, since you are doing it with other code.

[wayskobfssae]

DeeperThought, on 31 March 2011 - 08:27 AM, said:

You should be able to check the htmovflag of the projectile in EVENT_KILLIT to determine the wall it is hitting, if any. You can then calculate the wall angle by comparing the x and y coords of the wall point with the x and y of the the other wall point (the other wall point ID is in the point2 member of the wall struct), just as you would calculate the angle to make one actor face another. Make the projectile spawn the explosion using espawn, and then set the angle and whatever else you need to set on the explosion sprite(s). Define the projectile so it spawns nothing by default, since you are doing it with other code.

Excellent, TY. Yes, I already had the idea for how to calculate the wall angle, I just couldn't think of a way to get the wall's ID number from the projectile.

Good info too, so now I also know how to make bullets spawn blood when they hit a monster.

[Danukem]

wayskobfssae, on 31 March 2011 - 08:37 PM, said:

Excellent, TY. Yes, I already had the idea for how to calculate the wall angle, I just couldn't think of a way to get the wall's ID number from the projectile.

Good info too, so now I also know how to make bullets spawn blood when they hit a monster.

If the bullet is hitscan, then you should spawn the blood from the SHOTSPARK1 actor when the bullet hits, since there is no real projectile. For an example of this, you can check the code in DukePlus or in several other released mods. The key to making it work is getting data from the htg_t array in the SHOTSPARK1 actor: http://wiki.eduke32.com/wiki/Htg_t Specifically, you want htg_t 8

[High Treason]

Ugh... I can't figure out what is going wrong here, I know my DEF files are right because the tiles show up in Mapster32 and before they were set up as actors.

// Kuribo
define KURIBO1 8231
define KURIBO2 8232

action KURIBOANIM 8231 2 1 1 8

move KURIBOMOVE 0 32

useractor enemy KURIBO1 1 KURIBOANIM KURIBOMOVE
cstat 257
  ifhitweapon {
	// spawn something better when I have implemented it...
  	spawn BLOOD
    	killit
      	}
enda

In short, it is supposed to make the enemy walk in one direction once the player can see it, but all that happens is the actor is invisible in the game, some of the code executes, but it does not appear to move and is, as I said, invisible. This is happening with every actor I put in (with several other anomalies, but I can work around those).

Anybody got any ideas as to what is going on? I know I probably forgot something stupid.

[Danukem]

Try this. You should be able to figure out why it's better:

useractor enemy KURIBO1 1

  ifmove 0
  {
    move KURIBOMOVE geth
    sizeat 40 40
    action KURIBOANIM
    cstat 257
  }
  ifhitweapon {
        // spawn something better when I have implemented it...
        spawn BLOOD
        killit
        }
enda

[bullerbullerseven]

Yea, that was the problem i had too before DT told me that ifmove 0 is pretty important in an actor code.

[High Treason]

Yeah, that may be, I had to alter the move command to make the code work, but the actor still disappears when the action line is used, if I remove this a static Kuribo will move as I want it, but that does not explain why there is still a problem with the action command.

[Wolf]

High Treason, on 11 April 2011 - 04:44 PM, said:

Yeah, that may be, I had to alter the move command to make the code work, but the actor still disappears when the action line is used, if I remove this a static Kuribo will move as I want it, but that does not explain why there is still a problem with the action command.

Quote

define KURIBO1 8231
define KURIBO2 8232

action KURIBOANIM 8231 2 1 1 8

This is telling it to start the action on frame 16462. The first number in the action frame (in this case) should be 0.

[Danukem]

High Treason, on 11 April 2011 - 04:44 PM, said:

Yeah, that may be, I had to alter the move command to make the code work, but the actor still disappears when the action line is used, if I remove this a static Kuribo will move as I want it, but that does not explain why there is still a problem with the action command.

Heh, I see what you did. I didn't even look at your action definition before, but it's obviously wrong. It should look like this:


action KURIBOANIM 0 2 1 1 8

Remember, the first parameter of the action command is relative to the actor's defined tile number. Look at all the examples in the original CONs and look at the wiki if you don't understand.

[High Treason]

Funny thing is I read the wiki... knew it was something I had done but couldn't figure out why, that makes more sense than the way I tried doing it. Thanks for all the help. Now that one actor works I shouldn't need any help for quite a while until I do something else stupid. I always have problems with "action" and "move" - hopefully this will be the last time, in fact, I will bookmark this page for future reference.

[bullerbullerseven]

Remember that you can do the same with ai, ai is just actions and moves combined.

[SleeperService]

Hey guys, I'm a new user, and I hope this is the correct thread to post this question in.
I wanted to do some basic con editing - VERY basic con editing. Back in the days of running Duke 3D through MS DOS, editing the user.con for weapon damages, ammo capacities etc was relatively straightforward.

However, with the HRP and eDuke I've been having some difficulty making the requisite changes.

Basically, I edited the CON files for the following characterstics:

Ammo Capacity for specific weapons
Weapon Damage
Enemy HP
Ammo pick up amount

Of this, only the first change has been successful. I've tried changing the other variables but to no avail.

So then I tried replacing the USER.CON file in DUKE3D.GRP with Loom's GRP viewer, but when I try to run the eDuke executable, it says something about "failed to load art". I know the USER.CON file has been succesfully replaced, because it's size within the viewer had changed.

The weird thing is how that first change works, but the others don't - I'd have expected all the variables to display the same consistency, but the CON file seemed to be able to override the GRP without trouble - except only for that variable set.

[Danukem]

SleeperService, on 16 April 2011 - 07:40 PM, said:

So then I tried replacing the USER.CON file in DUKE3D.GRP with Loom's GRP viewer

Don't do that. Leave the edited USER.CON loose in your folder, and it will override the one inside DUKE3D.GRP

If you change those things you mentioned, it should work just like back in '96.

Without more information, I can't tell why only one of your edits is working. It's possible that you edited the wrong values. Attach a copy of your eduke32.log if you can't get it to work, and it should tell us if there's anything weird in your setup.