[XThX2]

Oh damn, it's been awhile since someone last posted in here... I hope I can get a reply for this one.

I have a tough problem with differentiating trails spawned by same kind of projectile. Here's what I'm trying to do :

* I'm trying to have my shotgun have ripper projectiles, the way I made it is similar to a railgun. It's "trails" do the damage, but to prevent from all trails doing damage I make it so that there's a variable to check if the target has taken damage from that set of rail trails. It is set to 0 in a short time so the target can get hit again.

* My problem => My shotgun has pellets and each pellet works in this logic. They spawn invisible trails to do the damage, with some limited range. Even if I'm too far (but still in trail's travel range) and even if one single pellet hits, it deals full damage of all pellets. I want to differentiate the trails of one pellet from those of other pellets, so I can make other pellets deal damage; also disabling the damage factor of all trails behind one of the pellets.

I'm sorry if I couldn't explain it better, but here's my code just in case :

state finishraildamage
				getactor[THISACTOR].owner owner //hitsprite
				ifvarn owner -1
				{
					ifvarvarn owner hitsprite // making sure enemy doesn't hit itself
					{
						getactor[hitsprite].htextra DMG
						addvarvar DMG randomvar4
						ifvare picnum UFORSAKEN { divvar DMG 4 mulvar DMG 3 } ifvare picnum ZOMBIER { setvar DMG -1 setvar htflag 1405 }
						ifvare picnum APLAYER { getplayer[THISACTOR].i ID ifvarvare ID owner { setvar DMG -1 setvar htflag 1405 } }
						setactor[hitsprite].htextra DMG
						ifactor FUSTRAIL ifvarg DMG -1 { getactor[hitsprite].extra DMG ifvarg DMG 0 sound LASGUNHIT }
						setactor[hitsprite].htpicnum htflag
						setvar returnvar1 1
					}
				}
ends

state railhurtcode
ifvarn returnvar1 1
{
	getactor[THISACTOR].x x
	getactor[THISACTOR].y y
	getactor[THISACTOR].sectnum TEMP
	getactor[THISACTOR].ang TEMPT
	sin my TEMPT
	cos mx TEMPT
	getactor[THISACTOR].z z
	getplayervar[THISACTOR].power_up POWERUPMODE
		hitscan x y z TEMP mx my 0 hitsect hitwall hitsprite hitx hity hitz CLIPMASK1

	ifvarn hitsprite -1
	{
		getactor[hitsprite].picnum picnum
		switch picnum
			case LIZTROOP
			case CDEMON
			case DEVIL
			case REVENANT
			case DEMON
			case CHAINGUNNER
			case CHAINGUNNER2
			case ZOMBIEPLS
			case DOUBLEGUNNER
			case TANK
			case BOSS1
			case BOSS2
			case PAINE
			case LSOUL
			case ENLISTEE
			case BLOODSEEKER
			case ZCAPTAIN
			case SHADE
			case IONIMP
			case UFORSAKEN
			case EXTERMINATOR
			case ROBOTGUARD
			case CACODEMON
			case SHOTGUNZOMBIE
			case SENTINEL
			case FSPIDER
			case APLAYER
			case HEAVYTROOPER
			case SHADOWSHIELD
			case ZOMBIER
			case BEAST
			case SOULCUBE
			case BIGIMP
			case BRUISERDEMON

			getactorvar[hitsprite].hitbysrail temp3
			ifvare temp3 1 nullop else
			{
				ifactor RIPPERTRAIL
				{
					setvar randomvar4 0
					randvarvar randomvar4 returnvar2 // RANDOM DAMAGE
					mulvarvar randomvar4 returnvar3 // MULTIPLIER
					ifvare randomvar4 0 setvarvar randomvar4 returnvar4 // MIN DAMAGE
					ifvarand POWERUPMODE 16 mulvar randomvar4 2
					setvar htflag SHOTGUNRIPPER
					
					state finishraildamage
					
					getactor[hitsprite].x mx
					getactor[hitsprite].y my
					getactor[hitsprite].z mz
					subvar mz 4096
					espawn JIBS6
					setactor[RETURN].x mx
					setactor[RETURN].y my
					setactor[RETURN].z mz
					
					setactorvar[hitsprite].hitbysrail 1 // There needs to be a variable for all types of rails, because then all trails would deal damage and it would be immense.
				}
			}			
			break
		endswitch
	}
}
ends

state resetrailstate // Reset the rail stuff as fast as possible
getactorvar[THISACTOR].hitbysrail railtemp
ifvare railtemp 1
{
	addvar railcount2 1
	ifvarg railcount2 0
	{
		setvar railcount2 0
		setactorvar[THISACTOR].hitbysrail 0
	}
}
ends

defineprojectile SHOTGUNRIPPER PROJ_WORKSLIKE 1
defineprojectile SHOTGUNRIPPER PROJ_SOUND -1
defineprojectile SHOTGUNRIPPER PROJ_EXTRA 12
defineprojectile SHOTGUNRIPPER PROJ_TRAIL RIPPERTRAIL
defineprojectile SHOTGUNRIPPER PROJ_TXREPEAT 45
defineprojectile SHOTGUNRIPPER PROJ_TYREPEAT 45
defineprojectile SHOTGUNRIPPER PROJ_TNUM 900
// defineprojectile SHOTGUNRIPPER PROJ_DECAL -1
defineprojectile SHOTGUNRIPPER PROJ_OFFSET 14354

useractor notenemy RIPPERTRAIL TOUGH
cstat 32768
ifvarn countvar 1
{
	setvar returnvar2 28
	setvar returnvar3 8
	setvar returnvar4 16
	state railhurtcode
	setvar countvar 1
}
else
killit
enda

[Danukem]

XThX2, on Dec 25 2010, 09:37 AM, said:

Oh damn, it's been awhile since someone last posted in here... I hope I can get a reply for this one.

I have a tough problem with differentiating trails spawned by same kind of projectile. Here's what I'm trying to do :

* I'm trying to have my shotgun have ripper projectiles, the way I made it is similar to a railgun. It's "trails" do the damage, but to prevent from all trails doing damage I make it so that there's a variable to check if the target has taken damage from that set of rail trails. It is set to 0 in a short time so the target can get hit again.

I'm back from my little vacation.

I don't feel like reading all that code, but based on your description it seems to me you could just use a timer. When something gets hit, check the victim's variable and don't do damage unless it is 0. If nonzero, cause the damage and set the variable to the desired timer length. Make the victim count down the timer in its own code.

[CruX]

Posted a tutorial over on the eDuke wiki, but since there hasn't been any tutorials over there in awhile, I'm slapping it up in this thread too, just to make sure it doesn't fly under the radar.
This is a relatively simple example that will allow the player to manually reload the pistol, like in DukePlus.

First, we'll declare the necessary gamevars...

gamevar PISTOLAMMO 0 1 
gamevar KICKBACK 0 1
gamevar PWEAPON 0 1 
gamevar PISTOLMAGAZINE 0 1
gamevar PERPLAYER1 0 1
gamevar WEAPON1_CLIP 0 0 // this last gamevar disable's the game's automatic reloading

then, under the APLAYER line in the game.con, we'll store our static variables that will be used, and code in a few functions that the reload is supposed to perform...

actor APLAYER MAXPLAYERHEALTH PSTAND 0 0
getplayer[THISACTOR].curr_weapon PWEAPON // the player's current weapon
getplayer[THISACTOR].kickback_pic KICKBACK // the frame of animation the player's weapon is at
getplayer[THISACTOR].ammo_amount 1 PISTOLAMMO // the player's pistol ammo

ifvare PWEAPON 1 { // if the player has the pistol selected...
ifvarl PISTOLMAGAZINE 1 { // and his magazine count is at zero...

getplayer[THISACTOR].weapon_pos PERPLAYER1 ifvarn PERPLAYER1 0 break // if he has a weapon that's lowering off screen, break


 else { ifvarl PISTOLAMMO 1 break else setplayer[THISACTOR].reloading 1 setplayer[THISACTOR].kickback_pic 4 } } // otherwise, if he has ammo for the pistol, start the reloading anim	  

ifvare KICKBACK 5 { // if the reloading animation is on its second frame...
ifvarg PISTOLAMMO 11 { setvar PISTOLMAGAZINE 12 } // if the player has at least twelve pistol rounds left, then set his magazine counter to a full magazine
else setvarvar PISTOLMAGAZINE PISTOLAMMO } } // otherwise set the magazine counter equal to his remaining ammo

Next we'll access the DOFIRE event, which is called if/when a weapon fires its projectile...

onevent EVENT_DOFIRE 

ifvare PWEAPON 1 { // if the player has the pistol selected when he fires a projectile...

ifvarl PISTOLMAGAZINE 1 break else { subvar PISTOLMAGAZINE 1 } } // subtract 1 from the magazine count, unless it's already at zero

endevent

In order to perform a reload, you'll need to assign it a key, which means booting out one of the game's more useless functions. In this example, it'll be the TURNAROUND key...

definegamefuncname 36 RELOAD // rename it, so it'll appear as RELOAD in the control settings menu

onevent EVENT_TURNAROUND 
setvar RETURN -1 // disable the event
ifvare PWEAPON 1 { // if the player has the pistol armed

 ifvare PISTOLMAGAZINE 12 break // and his magazine is full, break

else ifvarvare PISTOLMAGAZINE PISTOLAMMO break // if his magazine is equal to his pistol ammo, break

 else setplayer[THISACTOR].reloading 1 setplayer[THISACTOR].kickback_pic 4 } // otherwise, start the reloading sequence
endevent

Because the game's original reloading system is disabled, the player won't load in a clip when the game starts up. We'll take care of that, as well as another potential glitch, by accessing the RESET_PLAYER event.

onevent EVENT_RESETPLAYER
setvar PISTOLMAGAZINE 0 // if the player was reset to his starting position (i.e, he died), reset the clip amount to zero.
ifvare PWEAPON 1 { // if he has the pistol selected when he loads into the map...
setplayer[THISACTOR].reloading 1 
setplayer[THISACTOR].kickback_pic 4 } // start the reloading sequence.
endevent

The code that was under the APLAYER line made sure the player will automatically reload the pistol if his magazine's empty (and of course, he has the ammunition to do so), however he'll still shoot the projectile even if the magazine's empty, unless the firing key is disabled appropriately...

onevent EVENT_PRESSEDFIRE //when the player presses the fire button...
ifvare PWEAPON 1 { // and he has the pistol armed...
ifvarl PISTOLMAGAZINE 1 { setvar RETURN -1 } } // if his magazine is at zero, disable the firing key
endevent

And lastly, we're going to want the player to know what his magazine count's at, so we'll put a small counter next to the ammo amount...

onevent EVENT_DISPLAYREST
digitalnumberz 2930 280 175 PISTOLMAGAZINE 0 0 0 0 0 xdim ydim 50000 // display the magazine count at a slightly smaller size (50000) next to the ammo
endevent

[Danukem]

That looks nice, and probably cleaner and more efficient than what I cobbled together a few years ago.

One thing that people should understand is that by looking at tutorials like this they can learn a lot more than just how to add the feature in question. The basics of manipulating variables, members of the player struct, using game events and drawing to the screen are all there. There's also stuff like that in older tutorials.

That's why I get impatient with people who keep posting about one little thing they are trying to do, when I see no evidence that they are actively trying to learn by looking at existing code in released CON files, tutorials, etc.

Good job!

[Hendricks266]

I cleaned up the formatting on your tutorial so it looks a lot nicer and is a lot more understandable.

[Mblackwell]

DeeperThought, on Aug 24 2010, 01:15 PM, said:

AFAIK a grappling gun has never been coded for Duke. Getting the physics and look of the rope and hook right would be a lot of work. It would be much easier to make a grappling beam, with designated grappling points, like in the Metroid Prime series.

In fact I have some old sloppy code laying around that does something like that.

One thing you could do though if you just wanted a quick grapple like say, Batman's hooks, even if you sucked at math you could just code an invisible trail on a projectile and move the player to the sprites.

[Simon_Croes]

Could it be that there is something wrong with the code in the Manual Reloading Tutorial? It seems like when you reload that the magazine doesn't want to be resetted.
I perfectly included the code, no errors or whatsoever.

[CruX]

I just copy/pasted the code to a fresh install of DN3D and it worked without a hitch. Here's a few questions (sorry if they seem patronizing, but it's the best way to figure out what went wrong)

A) Did you copy the code to a con file that's been modified? If so, there's no guarantee the code will work with other code that's already been added (not without some extra modification, at least)
B ) When you copied the code beneath the APLAYER line, did you erase the APLAYER line itself? Two APLAYER lines could cause some problems if not an error itself.
C) When you copied the code, did you erase the notes that were slashed out on the sides? Those were only meant to help you understand what each step was doing, but if they were copied in with the code, they could possibly cause some kinks.

If the magazine isn't being reloaded, then something must be going wrong beneath the APLAYER line, because that's the only line in the code that actually reloads the magazine. If none of that helps, post your con file, and I'll take a look at it. Rest assure, though, I've done enough testing to know that it works.

[Simon_Croes]

Jep, I copied the code in a new fresh installed duke3D, I hadn't got 2 APLAYER lines so that wasn't the problem either. I removed the slashes like you told me, but it still got no different effect. The gamevars are on top of the game.con (under the includes). The code for the APLAYER is right under the APLAYER line. And all the rest (like the events) are in a separate con file and is included at the bottom of the game.con, maybe I am doing something wrong with that?

Thanks for helping me out

[CruX]

Could be. Try pasting all the events (in the order they appear) down at the very end of the game.con. If that doesn't help, post the con itself.

[Simon_Croes]

These are my con files I use.

Attached File(s)

•  GAME.CON (149.21K)
  Number of downloads: 921
•  Gamevars.con (143bytes)
  Number of downloads: 872

[CruX]

You got the code from the edited wiki entry, huh? Okay, makes sense now. Hate to pin in it on Hendricks, but when he edited the tutorial the first time, he messed up the brackets in the APLAYER line that made the clip refresh correctly.

Change the block of code that's beneath the APLAYER line to this...

  getplayer[THISACTOR].curr_weapon PWEAPON
  getplayer[THISACTOR].kickback_pic KICKBACK
  getplayer[THISACTOR].ammo_amount 1 PISTOLAMMO
  
  ifvare PWEAPON 1
  {
	ifvarl PISTOLMAGAZINE 1
	{
	  getplayer[THISACTOR].weapon_pos PERPLAYER1
	  
	  ifvarn PERPLAYER1 0 break
	  else ifvarl PISTOLAMMO 1
		break
	  else
	  {
		setplayer[THISACTOR].reloading 1
		setplayer[THISACTOR].kickback_pic 4
	  } }
	  
	  ifvare KICKBACK 5
	  {
		ifvarg PISTOLAMMO 11
		  setvar PISTOLMAGAZINE 12 
		else 
		  setvarvar PISTOLMAGAZINE PISTOLAMMO 
	  }
	}

When I opened your con file (as well as Hendrick's first edit), the code was like this - -

getplayer[THISACTOR].curr_weapon PWEAPON
  getplayer[THISACTOR].kickback_pic KICKBACK
  getplayer[THISACTOR].ammo_amount 1 PISTOLAMMO
  
  ifvare PWEAPON 1
  {
	ifvarl PISTOLMAGAZINE 1
	{
	  getplayer[THISACTOR].weapon_pos PERPLAYER1
	  
	  ifvarn PERPLAYER1 0
		break
	  else ifvarl PISTOLAMMO 1
		break
	  else
	  {
		setplayer[THISACTOR].reloading 1
		setplayer[THISACTOR].kickback_pic 4
	  }
	  
	  ifvare KICKBACK 5
	  {
		ifvarg PISTOLAMMO 11
		  setvar PISTOLMAGAZINE 12 
		else 
		  setvarvar PISTOLMAGAZINE PISTOLAMMO 
	  }
	}
  }  // this last bracket here is what did it. This belongs further up, beneath the code that sets the kickback pic to 4. With the code like this, the clip ONLY gets refreshed if the magazine count is less than zero.

You'll notice in the version of the tutorial on this thread, and the first version of the tutorial that was on the wiki, that bracket was where it belonged. Sorry for the confusion, I'll fix the wiki entry immediately.

[Simon_Croes]

Oh so that was what went wrong Well, thanks EmericaSkater. It works perfectly now!^^

[Hendricks266]

Sorry about that. I fixed the formatting on the brace and the level of indentation of the affected code. Try to keep it consistent.

[The Commander]

Hendricks loves to mess with peoples wiki pages, ugh.

[TerminX]

The Commander, on Mar 1 2011, 01:32 PM, said:

Hendricks loves to mess with peoples wiki pages, ugh.

Hendricks contributes more to the wiki lately than anyone else. It's a public resource and the pages don't "belong" to anyone.

[Hendricks266]

The Commander, on Mar 1 2011, 01:32 PM, said:

Hendricks loves to mess with peoples wiki pages, ugh.

I cleared out your talk page once because it was full of shit and I inadvertently made a mistake while optimizing EmericaSkater's code and making it so that newbies could actually read and understand what was previously a mess. Meddling?

http://wiki.eduke32....tructure_access
http://wiki.eduke32....fvar_conditions
http://wiki.eduke32....i/Findnearactor
http://wiki.eduke32.com/wiki/Spawn
http://wiki.eduke32.com/wiki/Shoot
http://wiki.eduke32....mevar_operators

I'd ban the spambots too but I'm not a sysop.

[CruX]

The Commander, on Mar 1 2011, 11:32 AM, said:

Hendricks loves to mess with peoples wiki pages, ugh.

He was just trying to help and it was the first contribution I've ever made to the wiki so it didn't really surprise me. I didn't know what I was doing in terms of formatting. Though I'll be honest, this - -

Hendricks266, on Mar 1 2011, 04:01 PM, said:

so that newbies could actually read and understand what was previously a mess.

is a bit exaggerated. I wouldn't really call a few brackets on the same line a "mess" that people wouldn't be able to understand.

[The Commander]

EmericaSkater, on Mar 2 2011, 02:55 PM, said:

is a bit exaggerated. I wouldn't really call a few brackets on the same line a "mess" that people wouldn't be able to understand.

I think Hendricks took what I said a bit to seriously, maybe if I had removed the ugh and replaced it with a
My talk page was never full of shit?

[bullerbullerseven]

I have to disagree with that, ugh

[m210®]

Quick question of Mapster32 script:
Is there a command to change the name of the sprite in 2D mode depending on the lotag. For example, sector effector actor with lotag = 2 drawn as SE:2 EARTHQUAKE name.

[Helixhorned]

It's already shown in the small sprite label in 2D view. The names themselves are hardcoded.

[m210®]

Yes, I know it I want make other sprite like SE and I thought it's possible via script

EDIT:
I mean changing name of my sprite via script in 2D mode

[Scott_AW]

Just edit names.h

Although it would be a nice feature.

[m210®]

Scott_AW, on Mar 4 2011, 07:38 AM, said:

Just edit names.h

Although it would be a nice feature.

It's not correctly right, because it's doesn't change name depending on lotag number
well, I'm understand now that it isn't possible

[Wolf]

I have a question. What would be the best theoretical way to add more weapons in the game? I'm thinking something along the lines of fifty weapons of various types. In fact, the best example would be that I want it like Counter-Strike, what with different types of SMG, rifles and whatnot. Just looking over the wiki, the path I've thought about was storing what kind of weapon the player has in a variable, then having one of the default duke weapon slots change stats/appearance accordingly. But I thought I'd ask in case there was perhaps a better way that the community could offer.

And then, a second question. I want my weapons to behave like the weapons in counter-strike. Meaning three things the weapons must be able to do.

-During the firing event, the weapon should play its entire shooting animation (from animated recoil to return-to-idle), but be able to be interrupted mid-animation for another shot if the firing rate settings allow it.
-Long reload animations.
-Misc. animation calls which prevent the player from firing until it's done. (Think attaching a silencer on the pistol from CS.)

But.. aren't all ingame animations bound to that.. preset kickback_pic thing?

Which.. the whole system there really confuses me, and I'm not really sure how to go about it all. Also, I say theoretical because I don't expect anyone to have to strain themselves by posting lengthy lines of code, thus doing the work for me.

[Danukem]

Wolf, on Mar 5 2011, 10:58 PM, said:

I have a question. What would be the best theoretical way to add more weapons in the game? I'm thinking something along the lines of fifty weapons of various types. In fact, the best example would be that I want it like Counter-Strike, what with different types of SMG, rifles and whatnot. Just looking over the wiki, the path I've thought about was storing what kind of weapon the player has in a variable, then having one of the default duke weapon slots change stats/appearance accordingly. But I thought I'd ask in case there was perhaps a better way that the community could offer.

And then, a second question. I want my weapons to behave like the weapons in counter-strike. Meaning three things the weapons must be able to do.

-During the firing event, the weapon should play its entire shooting animation (from animated recoil to return-to-idle), but be able to be interrupted mid-animation for another shot if the firing rate settings allow it.
-Long reload animations.
-Misc. animation calls which prevent the player from firing until it's done. (Think attaching a silencer on the pistol from CS.)

But.. aren't all ingame animations bound to that.. preset kickback_pic thing?

Which.. the whole system there really confuses me, and I'm not really sure how to go about it all. Also, I say theoretical because I don't expect anyone to have to strain themselves by posting lengthy lines of code, thus doing the work for me.

Make an entire system based on manipulating your own game variables, custom projectiles and screen drawing commands. For what you want, bypassing the hardcoded system entirely would be best. You were on the right track when you talked about using a single weapon slot and changing its characteristics depending on which actual weapon the player is using. But I would not even bother with things like kickback_pic. You only need to know enough about the hardcoded shit like that to be able to disable it. One thing to keep in mind is that you can make the player shoot any projectile at any time simply by using the shoot command in the APLAYER actor code. So you don't need to make one of the hardcoded weapons fire. You could have the player locked on the Mighty Boot weapon slot but be shown holding a gun, and make it shoot when you presses fire, etc.

[Helixhorned]

M210, on Mar 3 2011, 11:15 PM, said:

Yes, I know it I want make other sprite like SE and I thought it's possible via script

EDIT:
I mean changing name of my sprite via script in 2D mode

It's possible now, take a look at a.m32.
Basically you can code the little label to display anything you want, but I wouldn't mess with the predefined effector sprites.

[m210®]

ok, I'll try it Thanks for you post

EDIT:
Thanks a lot, it works

Attached thumbnail(s)

• 

[Jblade]

Wolf, on Mar 6 2011, 06:58 AM, said:

*snip*

What DeeperThought suggested is the best idea - one of my projects has over 80 weapons in itself and wrestling with the hardcoded nature of Duke's weapons is still a bit of a pain. It will simply be much better to code a seperate system and just disable Duke's stuff. You can recreate gun bobbing and stuff easily enough with some built in vars. It's also easier to manage ammo rather than the hard-coded stuff, if you want to have several categories of calibre rather than just saying 'MP5 ammo' or 'AK ammo' You can detect what key the player is pressing in the aplayer actor or one of the events, so using that you can tell the game to set the gun's animation to the first firing frame for high rate of fire weapons.

I also imagine you'll want to try and code the guns (eventually at some point) to become more inaccurate like in Counter-strike or Crossfire when you hold down fire. As far as I know event_shotrange is the only real way to modify accuracy for bullets - depending on the gun you'd have a variable controlling recoil that decreases accuracy the higher it gets (and naturally decreases when you don't fire)