[Danukem]

Mav3r1ck, on 28 November 2018 - 06:47 PM, said:

I was directed here in regards to con coding. I'm continuing from another topic I had recently posted.

onevent EVENT_GAME
  ifspawnedby APLAYER
    ifactor RPG
      spawn SMALLSMOKE
        sizeat 7 7
endevent

If I'm correct, this code is telling the game that Duke will fire the RPG with a thin smoke trail. The goal was to have it to where the Devastator rockets fired with a thin smoke trail. However, this will cause the larger rockets fired by the RPG to also have thin smoke trails. I'm trying to get it to where the Devastator will fire rockets with thinner smoke trails while the RPG fires rockets with the default smoke trails it comes with.

Some changes:

appendevent EVENT_GAME

ifactor RPG
  ifspawnedby APLAYER
    ife sprite[].xrepeat 7
{
  espawn SMALLSMOKE
  seta[RETURN].xrepeat 7
  seta[RETURN].yrepeat 7
}
endevent

Use "appendevent" because that will ensure it adds code to the event even if there are "onevent" or "appendevent" for it elsewhere. Note I am checking the size of the rocket. Rockets fired by the devistator are 7x7, and no other rockets in the game are that size. You don't even need the "ifspawnedby APLAYER" because the size should pick them out even without that. Super important: In CON, indenting does nothing, it's just for readability. So in your code, your "sizeat 7 7" was setting size on the RPG that is running the code, not on your spawned smoke. To set it on the thing you are spawning, you can use "espawn" which sets RETURN as the handle on the new sprite. Then you explicitly set size on the x/y repeat of the target sprite. Also note my use of { }

[Mark]

Its embarrassing when I get stuck on what should have been simple code and effect. But here we go again.
I created a working swing door with activator set to lotag 222. In my code there are a series of quotes displayed and sounds played for a short scripted conversation. Nothing special. Print quote, play sound, change spritepal and then repeat a number of times. It all works fine. Then in the final quote/sound ( shown below ) I also added "activate 222" so that the door would open after the quote and sound plays. But what happens is after the sound and quote play, the code loops on the activate and will proceed no further. Without "activate 222" the code continues along fine.

I'm evidently misunderstanding the activate command.

else ifspritepal 13
{
ifcount 90
{
sound SCORPBOSS5
quote 137
activate 222
resetcount
spritepal 14
}
}

EDIT: I found the problem. The wiki states that "activate" is the same but older version of " operateactivators". I changed to "operateactivators 222 0" instead and things are fine. If "activate" no longer works or needs something else for it to function the wiki should show that. GAH

[Mav3r1ck]

I noticed that some enemies in the game have a recog sound they use when Duke is first spotted by them. I want to add them in but I don't know where in the code to put them.

[Mark]

Probably near the "ifcansee" command for that enemy.

[Perro Seco]

I think it's better to use "ifai 0 sound XXX" in the beginning of the actor code, so they only sound the first time they spot Duke.

[Mav3r1ck]

Tried both suggestions but no luck.

[Danukem]

Mav3r1ck, on 01 December 2018 - 01:51 PM, said:

I noticed that some enemies in the game have a recog sound they use when Duke is first spotted by them. I want to add them in but I don't know where in the code to put them.

This problem was addressed recently when Firefly_trooper asked about it in one of his threads (not sure which). What's happening is some recog sounds are hardcoded to play when certain of the original enemies become activated (such as PIGCOP). I don't know why they made it that way, but they did. So, the sounds are not being triggered by anything in the CON code.

As for adding new ones, the suggestions above should work fine. Just play the sound when the enemy becomes active.

[Mav3r1ck]

Trooper Dan, on 01 December 2018 - 04:41 PM, said:

This problem was addressed recently when Firefly_trooper asked about it in one of his threads (not sure which). What's happening is some recog sounds are hardcoded to play when certain of the original enemies become activated (such as PIGCOP). I don't know why they made it that way, but they did. So, the sounds are not being triggered by anything in the CON code.

As for adding new ones, the suggestions above should work fine. Just play the sound when the enemy becomes active.

Yeah, I know the orginal stuff was hardcoded when I didn't seen any other recog sounds for the orginal enemies. I know what to do when adding the Recog sounds in the game.con but the problem is I don't know where exactly in the code to actually place it.

  {
    ifspritepal 0
      sound BOS2_RECOG
      ai AIBOSS2RUNENEMY
    else
    {

I did this so that the Cycloid will make a recog sound when facing Duke at the Stadium. with my limited knowledge of the game.con I decided to look through the NEWBEAST code for example to find a part of the code that resembled the Cycloid's to put it's recog sound in but to no avail. I know the recog sound needs to go in the part where it becomes active but I'm at a loss here. The enemies I'm looking to put this sound for is the Alien Queen and Protector Drone.

[Perro Seco]

This works for me:

ifai 0
{
  globalsound XXX
  ifspritepal 0
    ai AIBOSS2RUNENEMY
  else
  {
    strength 1
    sound BOS2_ATTACK ai AIBOSS2SHOOTENEMY
  }
}

I used globalsound to make it be heard everywhere. With sound you need to be very close to the Cycloid to hear it.

[Mav3r1ck]

Just used your example for the Overlord and Cycloid. Now I can hear the sounds much louder now. Still trying to figure it out for the Protector Drone and Alien Queen.

[Danukem]

Mav3r1ck, on 01 December 2018 - 07:27 PM, said:

Just used your example for the Overlord and Cycloid. Now I can hear the sounds much louder now. Still trying to figure it out for the Protector Drone

ifai 0
{
    ai AINEWBEASTGETENEMY
    sound NEWBEAST_RECOG
}

Mav3r1ck, on 01 December 2018 - 07:27 PM, said:

and Alien Queen.

ifai 0
{
    ai AIBOSS4LAYEGGS
    globalsound BOS4_RECOG
}

[Mav3r1ck]

Nice! thanks for your help Trooper Dan.

EDIT: And I put that at the beginning of state newbeastcode and state boss4code correct?

[Danukem]

Find and replace. For example,

ifai 0
    ai AIBOSS4LAYEGGS

is replaced with

ifai 0
{
    ai AIBOSS4LAYEGGS
    globalsound BOS4_RECOG
}

Everything not being replaced, including the lines that immediately follow, remain as before.

[Mav3r1ck]

I followed your example and encountered a problem. I found that same part of the coding in the Queen's code but when I changed it to what you have suggested something odd happens. Whenever the Queen spots Duke you hear the recog but the Queen instantly disappears for some reason.

Below is before the additional coding.

state boss4code

  ifai 0
    ai AIBOSS4LAYEGGS
  else
    ifaction BOSS4FLINTCH
    {
      ifactioncount 3
        ai AIBOSS4LAYEGGS
    }
  else
    ifai AIBOSS4LAYEGGS
      state boss4layeggs
  else
    ifai AIBOSS4SHOOT
      state boss4shootstate

  ifai AIBOSS4DYING
    state boss4dyingstate
  else
  {
    ifhitweapon
      state checkboss4hitstate
    else
      ifp palive
        ifpdistl 1280
      {
        addphealth -1000
        palfrom 63 63
      }
  }
ends

This is after the additional coding.

state boss4code

  ifai 0
  {
    ai AIBOSS4LAYEGGS
      globalsound BOS4_RECOG
  }
  else
    ifaction BOSS4FLINTCH
    {
      ifactioncount 3
        ai AIBOSS4LAYEGGS
    }
  else
    ifai AIBOSS4LAYEGGS
      state boss4layeggs
  else
    ifai AIBOSS4SHOOT
      state boss4shootstate

  ifai AIBOSS4DYING
    state boss4dyingstate
  else
  {
    ifhitweapon
      state checkboss4hitstate
    else
      ifp palive
        ifpdistl 1280
      {
        addphealth -1000
        palfrom 63 63
      }
  }
ends

[Danukem]

You can see clearly that all the addition is doing is playing the sound. I can only guess that you changed something else in a part of the code not shown that is making her disappear. None of the code you posted above could make the sprite disappear or delete etc.

[MC84]

Trooper Dan, on 07 November 2018 - 03:38 AM, said:

I believe the easiest solution is to simply spawn the envelopes using the mail command (or spawn paper money with cash -- it will make no difference), and then hack the displayed sprites to look like your leaf sprites. This assumes your leaf art is already in game somewhere. There are several steps needed to make this work, which I can help with if need be. But the basic idea is you use EVENT_ANIMATESPRITES to change what is displayed by the envelope sprite so it shows your leaf tile instead, even though it is still really an envelope.

Hi Dan, I've been sidetracked with other things but I've now done up a simple 5 frame leaf animation and have loaded it into mapster32. In terms of functionality I was planning on using the code you gave me for the damaged wall tiles (onevent EVENT_DAMAGEWALL) So that when a sector with the foliage texture is shot it will generate the leaves. I had a read of the EVENT ANIMATESPRITES wiki but my understanding is pretty limited. Is the first step to create a unique actor for my leaf sprite animation?

[Danukem]

conoklast, on 03 December 2018 - 03:10 AM, said:

Is the first step to create a unique actor for my leaf sprite animation?

No, I would start by using the mail command to spawn envelopes from the damaged wall using the code I gave you before. Once you confirm that the envelopes spawn and fall in the way that you want, then go about replacing their t-sprites with the sprites you made. If it doesn't work, then you'll just have to code the movement into your own actor by oscillating the xvel of the falling sprite using a sin function. Not super hard either way.

[Mav3r1ck]

Trooper Dan, on 02 December 2018 - 10:42 PM, said:

You can see clearly that all the addition is doing is playing the sound. I can only guess that you changed something else in a part of the code not shown that is making her disappear. None of the code you posted above could make the sprite disappear or delete etc.

I'm not sure if a I did or not. However, I'll delete the Queen's current code and replace it with the original and unaltered coding and use your example to see what happens.

EDIT: Got it working, but I don't remember editing the Queen's code at all. For now, all that's left is the Protector Drone.

state newbeastcode
  state checksquished
  ifai 0
  {
    cstator 257
    ai AINEWBEASTGETENEMY
  }
  else
    ifaction ANEWBEASTLYINGDEAD
  {
    fall
    state newbeastdyingstate
    break
  }
  else
    ifaction ANEWBEASTFROZEN
  {
    ifcount THAWTIME
    {
      ai AINEWBEASTGETENEMY
      spritepal 0
    }
    else
      ifcount FROZENDRIPTIME
    {
      ifactioncount 26
      {
        spawn WATERDRIP
        resetactioncount
      }
    }

    ifhitweapon
    {
      ifwasweapon FREEZEBLAST
      {
        strength 0
        break
      }
      addkills 1

      ifrnd 84
        spawn BLOODPOOL
      lotsofglass 60
      sound GLASS_BREAKING
      killit
    }
    ifp pfacing
      ifpdistl FROZENQUICKKICKDIST
        pkick
    break
  }
  else
    ifai AINEWBEASTJUMPENEMY
      state newbeastjumpstate
  else
  {
    fall
    ifai AINEWBEASTGETENEMY
      state newbeastseekstate
    else
      ifai AINEWBEASTCHARGEENEMY
        state newbeastseekstate
    else
      ifai AINEWBEASTFLINTCH
    {
      ifcount 8
        ai AINEWBEASTGETENEMY
    }

    else
      ifai AINEWBEASTDODGE
        state newbeastdodgestate
    else
      ifai AINEWBEASTSCRATCHENEMY
        state newbeastscratchstate
    else
      ifai AINEWBEASTFLEENEMY
        state newbeastfleestate
    else
      ifai AINEWBEASTTHINK
        state newbeastthinkstate
/*
    else
      ifai AINEWBEASTSHRUNK
        state newbeastshrunkstate
*/
    else
      ifai AINEWBEASTGROW
        state genericgrowcode
    else
      ifai AINEWBEASTDYING
        state newbeastdyingstate
    else
      ifai AINEWBEASTSHOOT
    {
      ifp pshrunk
        ai AINEWBEASTGETENEMY
      else
        ifcount 26
          ai AINEWBEASTGETENEMY
      else
        ifcount 25
          shoot SHRINKER
      else
      {
        ifcount 5
          nullop
        else
          ifcount 4
            sound NEWBEAST_SPIT
      }
    }
  }

  ifhitweapon
    state checknewbeasthit
ends

So do I do the same thing at the top of this code like for what I did with the Queen?

[Danukem]

Mav3r1ck, on 03 December 2018 - 01:57 PM, said:

So do I do the same thing at the top of this code like for what I did with the Queen?

[MC84]

Trooper Dan, on 03 December 2018 - 04:40 AM, said:

No, I would start by using the mail command to spawn envelopes from the damaged wall using the code I gave you before. Once you confirm that the envelopes spawn and fall in the way that you want, then go about replacing their t-sprites with the sprites you made. If it doesn't work, then you'll just have to code the movement into your own actor by oscillating the xvel of the falling sprite using a sin function. Not super hard either way.

I can confirm that the wall tile spawns money that behaves how I'd like it to. I had a go at mimicking the code from the wiki page but my code won't compile. I'll explain my thinking (or lack thereof )

So based on the wiki I need to assign 16 to the mdflags of the MONEY sprite/actor. I had tried renaming TEMP to LEAFVAR (just to make things clearer) but mapster didn't like this; said that it "...was expecting keyword, found "LEAFVAR"

 gamevar TEMP 0 0 
actor MONEY 1 LEAFFALL 0 0
getactor[THISACTOR].mdflags TEMP
orvar TEMP 16
setactor[THISACTOR].mdflags TEMP

Now I read through the ACTOR page on the wiki and after the name and strength values I need to define an action... so I created an action for my falling leaf sprite

define LEAF1 7642
useractor notenemy LEAF1 cstator 2305 ifaction 0 action LEAFFALL enda

action LEAFFALL 0 6 1 1 1 // my leaf sprite has 6 frames of animation

I then tried combining this with your previous code you had given me;

 damageeventtilerange 7653 7655 // 


onevent EVENT_DAMAGEWALL



ife wall[RETURN].picnum FOLIAGE1
{ money 7 
 gettspr[MONEY].tsprcstat TEMP
  ifvarand TEMP 2
      xorvar TEMP 2
  settspr[LEAF1].tsprcstat TEMP }
   
endevent 

I've no doubt made several errors, so if you can point me in the right direction it would be much appreciated.

[Danukem]

What follows is very hackish but it should get the job done.

IMPORTANT: Set your 6 frame leaf animation to animate from the art file (or using animtilerange if you aren't using .art files). That way, you can just set the money sprite to the leaf picnum and it will animate.

gamevar HACKTIME 0 0
gamevar spriteid 0 0
define LEAF1 7642
damageeventtilerange 7653 7655

onevent EVENT_DAMAGEWALL

ife wall[RETURN].picnum FOLIAGE1
{ 
  set HACKTIME YES
  money 7 
  set HACKTIME NO
}
   
endevent 

appendevent EVENT_EGS
  ifactor MONEY 
    ife HACKTIME YES
      seta[].mdflags 16
endevent

appendevent EVENT_ANIMATESPRITES

  gettspr[].tsprowner spriteid
  ife sprite[spriteid].picnum MONEY settspr[].tsprpicnum LEAF1 

endevent

[MC84]

Works a treat;

Link to youtube vid (embedding doesn't seem to work)

The only minor issue is that the leaves convert back to the money sprite as they touch the ground.

[Danukem]

conoklast, on 04 December 2018 - 03:46 AM, said:

Works a treat;

Link to youtube vid (embedding doesn't seem to work)

The only minor issue is that the leaves convert back to the money sprite as they touch the ground.

That link is not working but I will take your word for it. As for hitting the ground, I'm sure they are changing into a different picnum there (the middle tile of the money falling animation, which is tile 1234). What you could do is set a per-actor var on them in EVENT_EGS which will act as a flag for later. In EVENT_GAME you check any sprites of picnum 1234 that have the flag, and then change them to a leaf picnum which shows it on the ground.

[MC84]

Trooper Dan, on 04 December 2018 - 04:28 AM, said:

That link is not working but I will take your word for it. As for hitting the ground, I'm sure they are changing into a different picnum there (the middle tile of the money falling animation, which is tile 1234). What you could do is set a per-actor var on them in EVENT_EGS which will act as a flag for later. In EVENT_GAME you check any sprites of picnum 1234 that have the flag, and then change them to a leaf picnum which shows it on the ground.

Link to youtube vid

The link should work now - I figured you might be interested seeing as you're the one providing all the code. I will try to implement the per-actor VAR by myself and will see how I go.

[OpenMaw]

conoklast, on 04 December 2018 - 12:31 PM, said:

Link to youtube vid

The link should work now - I figured you might be interested seeing as you're the one providing all the code. I will try to implement the per-actor VAR by myself and will see how I go.

It doesn't.

[MC84]

Yep l had the vid marked as private instead of unlisted. Hopefully it will work now.

[Mav3r1ck]

So I got some more scripting questions.

1. I was able to properly code in an Overlord Sentry using Hendricks266 tutorial from the Eduke32 wikia. Though I noticed that it's missile firing position was off on the Overlord Sentry and from what I understand this will cause it to shoot itself at certain angles and even kill itself. How do I fix this?

2. I want to make an indestructible corpse/invisible corpse. How can I do this?

[Danukem]

Mav3r1ck, on 05 December 2018 - 04:49 PM, said:

So I got some more scripting questions.

1. I was able to properly code in an Overlord Sentry using Hendricks266 tutorial from the Eduke32 wikia. Though I noticed that it's missile firing position was off on the Overlord Sentry and from what I understand this will cause it to shoot itself at certain angles and even kill itself. How do I fix this?

I'm pretty sure it will not shoot itself if you are using a relatively recent EDuke32. Verify that it does before worrying about it. If the position of the rockets bothers you, there are fixes but you will need to be more specific about the positioning.

Mav3r1ck, on 05 December 2018 - 04:49 PM, said:

2. I want to make an indestructible corpse/invisible corpse. How can I do this?

All you have to do is change cstat on the corpse.

https://wiki.eduke32.com/wiki/Cstat

EDIT: I should add, if the corpse is coded to be destroyed when hit with splash damage ("ifhitweapon RPG ...") then obviously you should remove that code for the corpse in question.

[Mav3r1ck]

Trooper Dan, on 05 December 2018 - 05:16 PM, said:

I'm pretty sure it will not shoot itself if you are using a relatively recent EDuke32. Verify that it does before worrying about it. If the position of the rockets bothers you, there are fixes but you will need to be more specific about the positioning.

Hmm, the firing position does bother a little. The rockets spawn above the Overlord Sentry. I also understand that when monsters are scaled the projectiles will match the scaled monster.

Trooper Dan, on 05 December 2018 - 05:16 PM, said:

All you have to do is change cstat on the corpse.

https://wiki.eduke32.com/wiki/Cstat

EDIT: I should add, if the corpse is coded to be destroyed when hit with splash damage ("ifhitweapon RPG ...") then obviously you should remove that code for the corpse in question.

The code below is what I have for an experiment.

    ifwasweapon RPG
    {
      sound PRED_DYING
      sound SQUISHED
      state troop_body_jibs
      state standard_jibs
      cstat 0
      iffloordistl 8
      sound THUD
      ifrnd 64
        spawn BLOODPOOL
      state rf
      strength 0
      move TROOPSTOPPED
      action ATROOPDEAD
      cstator 32768

This will allow me to blow up the Trooper but it will leave an invisible corpse behind and will respawn in the spot where it died. The goal is to attempt to replicate Doom's Nightmare difficulty respawning and by that I mean to have the monsters respawn regardless of what weapon you kill them with. So far it's been successful but the issue I'm facing is that if you shoot an explosive at the invisible corpse it will explode with guts until the monster respawns. I'm trying to get it to where it doesn't do this.

[Danukem]

There might be hardcoded positioning specific to BOSS3. If that's the case, you could probably remedy that using "cactor COMMANDER" right before "shoot RPG" then immediately after use "cactor BOSS3". If my suspision is correct that will make the RPG spawn lower. It will also probably reduce the damage quite a bit, and if that's a problem there is a solution for that as well.

As for the invisible corpse problem, I would define a new move, let's say "move JIBRESPAWN" and then when killed by RPG or RADIUSEXPLOSION, you have the enemies use that move instead of "move TROOPSTOPPED" or whatever that particular actor uses. Then, in the actor's code where the corpse is checking for explosions, add the line "ifmove JIBRESPAWN break" before any of the code that makes them spawn jibs. But also make sure that the "ifrespawn" check happens before the break, otherwise they will be stuck invisible forever. You migth have to move some code around to make it work.