[Fox]

Yes, setactorvar is meant to be used to set variables in other actors, you shouldn't use it for THISACTOR, just setvar.

[Reaper_Man]

It seems that htextra isn't being populated in EVENT_GAME. Here's my code, it works fine if I have it in the actual actor code, but it never seems to trigger in the event.

onevent EVENT_GAME
{
	getactor[THISACTOR].extra hptemp
	ifvarg hptemp 0
	{
		getactor[THISACTOR].htextra enemytemp
		ifvarn enemytemp -1
		{
			getactor[THISACTOR].htowner playertemp
			getplayer[THISACTOR].i playertemp2
			ifvarvare playertemp playertemp2
			{

Am I doing something totally wrong here?

[Danukem]

I think the problem is that EVENT_GAME code is executed after the actor's code is executed. Actors typically already have a check for ifhitweapon, which resets htextra. By the time your EVENT_GAME code is executed, the damage has already been processed.

What I do is create a state and make the actors call it from their actor code, before their call to ifhitweapon.

[Reaper_Man]

Yeah that's what I've done for now. I was just hoping to not have to make any edits to enemy code at all, though.

[Danukem]

 Reaper_Man, on 26 July 2012 - 12:09 PM, said:

Yeah that's what I've done for now. I was just hoping to not have to make any edits to enemy code at all, though.

Maybe this would work?

gamevar lastextra 32767 2

onevent EVENT_GAME

ifvare sprite[THISACTOR].statnum 1
ifvarvarl sprite[THISACTOR].extra lastextra
ifvarvare sprite[THISACTOR].htowner player[THISACTOR].i
{
     // do your stuff here
}

getactor[THISACTOR].extra lastextra

endevent

[Fox]

But that's kind of lame, since it only checks if the health is not the same. Depending this may not properly return damage since the damage can be zero. In the end using htextra in the actor code is the better choice for all tests I have done.

If I am not wrong, the problem is that ifhitweapon command seems to do more than checking for damage, but also re-calculates it when used, so you can't use htextra after it.

====//====//====

How can I find out if music option in menu is on or off?

[Reaper_Man]

It's also a problem if a shot would kill an enemy and you do changes to the damage that wouldn't actually kill them, they die but then they're not dead and it kind of spazzes out. That's really unfortunate.

I also didn't realize that something like ifvarvare sprite[THISACTOR].htowner player[THISACTOR].i would work, that's useful to know.

[Fox]

If you are using it inside the player actor, player[THISACTOR].i is the same as THISACTOR.

[Danukem]

 Fox, on 26 July 2012 - 01:36 PM, said:

But that's kind of lame, since it only checks if the health is not the same.

I know it's lame, but he has good reason to not want to modify the enemy code. Once you start doing that, your code becomes much less portable.

[Reaper_Man]

Precisely.

[Hendricks266]

 Trooper Dan, on 26 July 2012 - 12:06 PM, said:

I think the problem is that EVENT_GAME code is executed after the actor's code is executed. Actors typically already have a check for ifhitweapon, which resets htextra. By the time your EVENT_GAME code is executed, the damage has already been processed.

That's a serious problem for mutators, and unfortunately I can't think of a simple solution. Perhaps a second EVENT_GAME should be added before the actor block executes, but that seems like overkill for a corner case like this.

Do you know of any other instances where there is something you cannot do in EVENT_GAME that you can effectively only do in actor code?

[Reaper_Man]

Assuming that making a change so EVENT_GAME executes before instead of after is out of the question, I don't think having something like EVENT_PREGAME would be used exclusively for damage handling. Having both would (correct me if I'm wrong in my thinking here) allow you to set a variable in PREGAME, allow it to get modified during the actor's code, and then used/checked/whatever during GAME. But even if that's not the case, the more tools for modders the better, right?

[Reaper_Man]

Another question: How should I properly access actors that are spawned via respawns? Neither EVENT_SPAWN nor EVENT_EGS seem to grab them.

[Danukem]

 Reaper_Man, on 27 July 2012 - 03:59 PM, said:

Another question: How should I properly access actors that are spawned via respawns? Neither EVENT_SPAWN nor EVENT_EGS seem to grab them.

onevent EVENT_EGS

ifspawnedby RESPAWN
{
// etc.

Works for me!

[Reaper_Man]

Hmm you're right that works. Must be something else in my code that's treating map placed actors different than spawned actors. I'll dig deeper, thanks.

Okay you're partly right. The problem is that the picnum of the spawned sprite is the literal picnum, IE a spawned LIZTROOPJETPACK's picnum is 1725 and not 1680 as would be expected. Is this a bug, or do I need to add in every spawn variant of every enemy actor?

[Fox]

Yes, you should add each instance.

[Reaper_Man]

That sucks. =\

[Danukem]

 Reaper_Man, on 27 July 2012 - 04:41 PM, said:

Okay you're partly right. The problem is that the picnum of the spawned sprite is the literal picnum, IE a spawned LIZTROOPJETPACK's picnum is 1725 and not 1680 as would be expected.

It's not a bug; the behavior makes perfect sense. For example LIZTROOPJETPACK does not cactor into a regular LIZTROOP until it's actor code runs, but that can't happen until after EVENT_EGS.

It just takes a few moments to write code such as this:

		getactor[THISACTOR].picnum picnum
		switch picnum
		case LIZTROOP
		case LIZTROOPSTAYPUT
		case LIZTROOPSHOOT
		case LIZTROOPJETPACK
		case LIZTROOPRUNNING
		case LIZTROOPONTOILET
		case LIZTROOPJUSTSIT
		case LIZTROOPDUCKING
                // do whatever
                break
                case PIGCOP
                case PIGCOPDIVE
                case PIGCOPSTAYPUT
                // etc.

[Biturbo]

Hello, can someone help me with this:

i need replace original crosshair by my own texture, but why is black color transparent?
For test i replaed original crosshair with black 64x64 bmp in .ART and in HRP with 64x64 black png.
But in game its transparent black, why? Is there any control of transparency of crosshair?

And how i can control if is crosshair off / on?
I know about event_displaycrosshair in HUD file, but how exactly it works?

[sedition]

Is there a way to control the position of the main menu of the game. So I want to place it in the bottom left corner instead of having it in the middle of the screen.

I know, the problem would be the different screen resolutions, but can´t I just give it a %-value?

[Mblackwell]

At the current time there's no ability to change the menus without editing the source code unfortunately.

[Biturbo]

How i can simulate something like sector effector?

I placed my custom sprite in sector which i want do that effect of lighting. But there is problem, its working only for first sector, i need it for all sectors where is that sprite placed...
can someone help?

define LIGHTING_ICON 3589
gamevar timecounter 0 0
gamevar okay 0 1
gamevar sector_pos 0 0

onevent EVENT_DISPLAYROOMS

 ifrnd 0
 {
  ifrnd 64
  {
    soundonce THUNDER
    setvar okay 1
  }
 }

endevent

useractor notenemy LIGHTING_ICON
{
cstat 32768

getactor[THISACTOR].sectnum sector_pos

ifvare okay 1
{

setsector[sector_pos].floorshade 20
setsector[sector_pos].ceilingshade 20
addvar timecounter 1
setvar okay 1
}

ifvare timecounter 40
{
setsector[sector_pos].floorshade 30
setsector[sector_pos].ceilingshade 30
setvar timecounter 0
setvar okay 0
}

}
enda

[Jblade]

You've made the gamevar sector_pos a global one - you'll need to change it to a per-actor variable by changing it's definition to this:

gamevar sector_pos 0 2

The wiki tells you different values you can set gamevars, but for the most part you'll be using 0 as a global var, 1 as a player var, and 2 as an actor var. You'll also want to change timecounter to a per actor var, judging by your code

[Biturbo]

 James, on 06 August 2012 - 06:38 AM, said:

You've made the gamevar sector_pos a global one - you'll need to change it to a per-actor variable by changing it's definition to this:

gamevar sector_pos 0 2

The wiki tells you different values you can set gamevars, but for the most part you'll be using 0 as a global var, 1 as a player var, and 2 as an actor var. You'll also want to change timecounter to a per actor var, judging by your code

Many Thanks i didnt know this (im just a new to .CON) but problem is it still doesnt work...

If i do this:

define LIGHTING_ICON 3589
gamevar timecounter 0 2
gamevar okay 0 0
gamevar sector_pos 0 2

onevent EVENT_DISPLAYROOMS

 ifrnd 0
 {
  ifrnd 64
  {
    soundonce THUNDER
    setvar okay 1
  }
 }

endevent

useractor notenemy LIGHTING_ICON
{
cstat 32768
getactor[THISACTOR].sectnum sector_pos

ifvare okay 1
{
setsector[sector_pos].floorshade 20
setsector[sector_pos].ceilingshade 20
addvar timecounter 1
}

ifvare timecounter 40
{
setsector[sector_pos].floorshade 30
setsector[sector_pos].ceilingshade 30
setvar timecounter 0
setvar okay 0
}

}
enda

Then it isnt working properly, first one sector goes dark and return back, later another one, but both never goes dark and return together.
I tried also this without that "setvar okay 0":

ifvare timecounter 40
{
setsector[sector_pos].floorshade 30
setsector[sector_pos].ceilingshade 30
setvar timecounter 0
}

and its really close to what i need, but still is there problem, when both sectors goes dark, they keep blinking...
So we are very close, just tell me someone what im doing bad why they are blinking...

[Mblackwell]

Your "okay" variable shouldn't be set by the effectors themselves. Since it's a global variable it's getting overridden each time. Set it to 1 or 0 in the APLAYER code.

[Biturbo]

Ive tried but still its doesnt work
cant you show me exactly i how can do it?
because ive tried many combinations of this + that aplayer code, but still it isnt working properly.
video is here: video
im trying to make own mod, something like slendergame.net with nice atmosphere, but first problem is these lighting, and another one is i dont know how control if is crosshair on or off.
I know maybe in some data or cfg file can be this information stored, but that isnt very useful because i need control it in .CON

I'd appreciate any help, thanks!

[rasmus thorup]

For the crosshair http://wiki.eduke32.com/wiki/Crosshair Use this to disable it via CON. Once it is disabled, display a custom texture on the screen with a screen drawing command. http://wiki.eduke32.com/wiki/Scripting try and look at the bottom

[Mblackwell]

Biturbo, on 07 August 2012 - 05:25 AM, said:

cant you show me exactly i how can do it?

gamevar thunder_count 0 0

gamevar runonce 0 2
gamevar default_cshade 0 2  // to store the original sector shade
gamevar default_fshade 0 2 // to store the original sector shade
gamevar new_cshade 0 2
gamevar new_fshade 0 2

useractor notenemy LIGHTING_ICON

    cstat 32768
    ifvare runonce 0 // we only want to store the shade at its default value
    {
        getsector[THISACTOR].floorshade default_fshade
        getsector[THISACTOR].ceilingshade default_cshade
        setvar runonce 1
    }


    ifvarg thunder_count 30 // if the counter is above a good value
    {
        setvarvar new_cshade default_cshade
        setvarvar new_fshade default_fshade
        
        subvar new_cshade 10 // subtract! lower numbers are brighter numbers
        subvar new_fshade 10
        ifvarg thunder_count 35 // I made two stages of brightness for the heck of it
        {
            subvar new_cshade 10
            subvar new_fshade 10
        }
        setsector[sector_pos].floorshade new_fshade
        setsector[sector_pos].ceilingshade new_cshade
    }
    else // otherwise just keep the default/original sector shade
    {
        setsector[THISACTOR].floorshade default_fshade
        setsector[THISACTOR].ceilingshade default_cshade
    }
    
enda

actor APLAYER

    ifvare thunder_count 0 ifrnd 16 // we only start counting sometimes
    {
        setvar thunder_count 1
    }
    else ifvarg thunder_count 0 // count as long as the var is more than 0
    {
        addvar thunder_count 1
        ifvarg thunder_count 40 // reset it when it goes over the max value we want
            setvar thunder_count 0
    }
    // rest of player code
    
enda

[Hendricks266]

rasmus thorup, on 07 August 2012 - 11:27 AM, said:

For the crosshair http://wiki.eduke32.com/wiki/Crosshair Use this to disable it via CON. Once it is disabled, display a custom texture on the screen with a screen drawing command. http://wiki.eduke32.com/wiki/Scripting try and look at the bottom

That is circuitous. Use getuserdef[THISACTOR].crosshair only to see if the user has enabled or disabled the crosshair in their options. You should not change it because that would alter their preference.

Instead, utilize EVENT_DISPLAYCROSSHAIR. If you want to forcefully disable the crosshair, in that event, "setvar RETURN -1". If you only want to change the crosshair image, I added functionality so that all you have to do is set RETURN to the tilenum of the image you want to use. If you are doing anything more fancy than that, such as color palette or positioning changes, let me know and I will help you with that.

[Reaper_Man]

Hendricks266, on 26 July 2012 - 06:21 PM, said:

That's a serious problem for mutators, and unfortunately I can't think of a simple solution. Perhaps a second EVENT_GAME should be added before the actor block executes, but that seems like overkill for a corner case like this.

Do you know of any other instances where there is something you cannot do in EVENT_GAME that you can effectively only do in actor code?

So hey, now that you've got your new computer, any chance of this happening soonish? I'm sort of bedridden post-surgery for the next couple of days, I'd love to be able to finish up that mutator I was working on.