[Helixhorned]

Not by itself, but if you insist that it has to be SE7 you'll have to deal with a lot of working around hardcoded stuff. Pressing SPACE to teleport yourself is coded in a.m32, albeit under slightly different conditions. Duke3D will likely add some more complications.

[CruX]

insane_metalhead, on 21 September 2011 - 02:13 PM, said:

Can somebody help me to code a new sort of teleportation method? What I want to do is when standing in a sector (SE7) you have to hit space to teleport. Is this difficult to do?

It'll be a lot easier if you just create two user actors to execute the code instead of trying to mess around with an SE. Attached is a rough version of the effect. The code's all at the bottom of the game.con therein, but I'll post it here for the sake of explaining it. Course, if someone else has a more efficient way of doing it, feel free to tell me; this is just something I whipped up in about five minutes.

gamevar hitagsaved 0 2 // var used for grabbing the hitag from the actor right when it's loaded into the map
gamevar temphitag 0 2 // temporary var used for storing the hitag as an actorvar 
gamevar fakehitag 0 2 // var used for the storing the hitag value so it can be read in actor code. 
gamevar GLOBALHITAG -1 0 // a global var that will be set when the "START" teleport actor is engaged.
gamevar x 0 2 
gamevar y 0 2
gamevar z 0 2 
gamevar sector_actor 0 2
gamevar sector_player 0 2 // just position/sector variables. 

define TELEPORTSTART 3328 // the actor that the player engages
define TELEPORTEND 3329 // the actor that changes the player's coordinates

eventloadactor TELEPORTSTART // when the TELEPORTSTART actor is loaded into the map...
getactor[THISACTOR].hitag hitagsaved // get its hitag value
setactorvar[THISACTOR].temphitag hitagsaved //  and set the "temphitag" variable to whatever that value is
setactor[THISACTOR].hitag 0 // then set the hitag to zero.
enda

eventloadactor TELEPORTEND // and do the same thing for the TELEPORTEND actor 
getactor[THISACTOR].hitag hitagsaved
setactorvar[THISACTOR].temphitag hitagsaved
setactor[THISACTOR].hitag 0 
enda

useractor notenemy TELEPORTSTART 0 
cstat 32768 // make it invisible
getactorvar[THISACTOR].temphitag fakehitag // set the "fakehitag" variable equal to the value of the "temphitag" variable
getactor[THISACTOR].sectnum sector_actor 
getplayer[THISACTOR].cursectnum sector_player // get the sector number of both the player, and the TELEPORTSTART actor...
ifvarvare sector_actor sector_player // if they're equal (i.e the player is in the same sector as the TELEPORTSTART actor)...
{
ifhitspace { // if the player hits space...
ifcount 15 {

setvarvar GLOBALHITAG fakehitag resetcount // set the "GLOBALHITAG" variable equal to the value of the "fakehitag" variable. 
  }
 }
}
enda

useractor notenemy TELEPORTEND 0 
cstat 32768
getactorvar[THISACTOR].temphitag fakehitag // again, set the "fakehitag" variable 
getactor[THISACTOR].sectnum sector_actor
getactor[THISACTOR].x x
getactor[THISACTOR].y y
getactor[THISACTOR].z z  // grab the "TELEPORTEND" actor's x, y, z coordinates and sector number
ifvarvare GLOBALHITAG fakehitag { // if the "GLOBALHITAG" variable is equal the the "TELEPORTEND" actor's "fakehitag" variable...
setplayer[THISACTOR].cursectnum sector_actor 
setplayer[THISACTOR].posx x
setplayer[THISACTOR].posy y // set the player's sector, x and y coordinates equal to the "TELEPORTEND" actor's...
subvar z 6500 // subtract 6500 from the "TELEPORTEND" actor's z-coordinate. (If this isn't done, the screen will briefly flicker towards the floor upon teleporting)
setplayer[THISACTOR].posz z // set the player's z-coordinate equal to the new z-coordinate. 
setvar GLOBALHITAG -1 } // and reset the "GLOBALHITAG" so it can be done all over again. 
enda

The map makes it clear-cut enough, but basically all you do is take a "TELEPORTSTART" actor and a "TELEPORTEND" actor, put them at two different parts of the map, then give them matching hitags.

Attached File(s)

•  teleport.zip (304.66K)
  Number of downloads: 779

[Simon_Croes]

This is great EmericaSkater! Thanks for the quick reply. This is exacly what I needed

[Simon_Croes]

One more little thing that I was wondering about for a few months. When playing in polymer and you teleport (blue flash), have the shrinker/expander (green/red light effect) or freezegun (blue projectile light) there will always be a light that is propably coded in the source. Is it possible to turn these kind of things off with for example command line or con code?

Thanks in advance

[Danukem]

I wish there was a way to prevent the pistol from automatically hitting any enemy under the crosshair no matter how far away the enemy is. If it were a weapon flag, then it could be removed, or applied to any other hitscan weapon.

While on the subject of hitscan weapons, it is still not possible to adjust the accuracy of hitscan weapons fired by nonplayers. I know James wanted that as well, and probably other modders.

[Jimmy]

Not trying to be an ass here, but wouldn't that kinda defeat the point of a hitscan in the first place? Why not use a projectile with a high velocity instead?

[Mblackwell]

You could adjust the accuracy by jittering the angle before firing.

Also there are projectile flags for autoaim iirc. You could make a new hitscan projectile.

[Danukem]

@CA: No it would not defeat the purpose of hitscan. Projectiles with high velocity have many other properties that make them different from hitscan. For example, it is quite a trick to make a nonhitscan projectile leave decals.

@Mblackwell: There are no projectile flags that will make monsters shoot hitscan in a straight line. There is a random component to the trajectory that is automatically applied when they fire. In the player, it can be controlled (albeit crudely by powers of 2) in EVENT_GETSHOTRANGE, but there is no corresponding event or way of controlling it for nonplayers.

[Hendricks266]

Maybe some of the newer PROJ_WORKSLIKE flags (near the bottom) do what you want.

[Danukem]

Hendricks266, on 11 October 2011 - 04:30 PM, said:

Maybe some of the newer PROJ_WORKSLIKE flags (near the bottom) do what you want.

LOL, I haven't looked at that list in a while, and I didn't know there was a FLAG_ACCURATE

[Fox]

Is it possible to add a "BOUNCESOFFWALLSONLY" flag, which won't bounce if hit the floor?

[tetsuo the prophecy]

Hi fellow dukers! The name is Tom, and I have been an avid Duke Nukem 3D player since the game came out. I'm 27 years old, and I still love this game to death!

Anyhow, I'm collaborating with a cyber cafe in my hometown on a project; the project is to bring a Duke Nukem 3D network game to the customers and create a tournament. We're using eDuke32 to make this possible.

The thing we are most challenged with right now is scripting certain parameters (triggers for rotating maps when a quota is met e.g. kill count or timer).

Could anybody give us any direction on how to go about this, if possible?

Thanks!

- Tom

[rasmus thorup]

You can find the all the stuff you need here http://wiki.eduke32.com/wiki/Main_Page
You need to get into gamevars.

[Jimmy]

I think he's asking for command line parameters, not how to code.
This should help you.

[rasmus thorup]

Are you sure? Kill counter control with command lines?

[Danukem]

rasmus thorup, on 14 October 2011 - 03:42 PM, said:

Are you sure? Kill counter control with command lines?

I think C.A. is right. The post talked about "parameters" and it's normal for multiplayer games to have an option for switching maps after a certain number of kills or after a certain amount of time without extra scripting.

[Jay]

How do i spawn monsters in eduke32 dukeplus pack atomic edition in a user map

[Danukem]

http://wiki.eduke32....onsole_commands

example:

spawn PIGCOP

types in the console of course

[Zaxtor]

Is it possible to make example a weap shoot 2 diff projectiles BUT only when a var is set. it spawns an extra projectile.
Without the var set is the ordinary knee (claw)

For my mod the knee is a claw because the player is a wolverine he uses his claw instead of using his knee like duke does use the knee/boot.

When I did a test with the knee (num 2521) the thing only spawns on IMPACT of the knee (claw) as it must touch something to spawn w/e. It doesn't move because when you spawn a projectile by (spawn) it wont move if is a projectile i.e missile, shrink spark etc.
What I wanna make is it shoots it without being obligated to hit something to spawn it.


defineprojectile 2521 PROJ_WORKSLIKE 16
is the actual code for the (knee)

Also the projectile I've made I want to shoot when he uses claw if the var is set

defineprojectile 4808 PROJ_WORKSLIKE 2
defineprojectile 4808 PROJ_VEL 320
defineprojectile 4808 PROJ_EXTRA 17
defineprojectile 4808 PROJ_HITRADIUS 856
defineprojectile 4808 PROJ_SPAWNS EXPLOSION2

is a powerball that explodes on impact

So I wanna try to make so when as soon you hit the button 1 which throws the kick (claw for my mod) it shoots something but only when a var is set.
I'm making a "Weapon addon" that you get when you risk your life by searching it by going deep down.

Like ifvare POWERBALL 1 { that code to make the thing shoot that projectile while using the melee weap }


In my mod OBLIVION I had a similar thing. Example when you grab a booster the weap makes a deadlier explosion.
But the weap spawns an invisible sprite (on impact or by making trails) that dies instantly if no var is set.
but when is set it makes the deadly explosion or a trail of energy for its trail. But as above is diff.

[rasmus thorup]

Hi Zaxtor.
You have made a working projectile. What you need to change is the weapon itself.
http://wiki.eduke32....efined_gamevars
Look at the mighty foot. Change WEAPONx_FIREDELAY to a lower number.
Now i wonder. Have you made the wolverine claws animation? You might want to change WEAPONx_TOTALTIME to make the animation "fit".
I hope i didn't misunderstand the question >.>

[Zaxtor]

His claw is animated, been done since the beginning of time.

I'm trying to make so example if I take something it sets a var and when I use the weap 0.
Without the var set is just the normal claw. and it ignores the "defineprojectile 2521 PROJ_WORKSLIKE 2" in knee/claw defineprojectile

It will still display the claw but shoot a projectile (power ball that explodes on impact just like the rpg)
But I want it to fire as soon u press 0.

Forgot to say before,..

If I mix 2 define projectiles in the knee (claw for my mod).

Example v

defineprojectile 2521 PROJ_WORKSLIKE 16
defineprojectile 2521 PROJ_WORKSLIKE 2
defineprojectile 2521 PROJ_SPAWNS POWERBALL_1


The thing will still punch but shoot a punch while pressing 0 that explodes on impact.
But is VERY close of what I want. As means only 1 error to be fixed. making so when it shoots it shoot 4808 instead of 2521

But it shoots the image of the claw or kick w/e. For me is the claw cus is the first frame of the knee replaced by a claw.
So I wanna make so it shoots the projectile I want (its sprite number is 4808)

[rasmus thorup]

It's very hard for me to understand what you need.
But if you want to change what projectile the weapon of your choice shoots, this is the place http://wiki.eduke32....efined_gamevars
WEAPONx_SHOOTS controls what projectile the weapon shoots.

[Zaxtor]

I think i'll drop it and try to do it for a projectile shooting weap instead.
Since is easier than a non projectile weap

[Jblade]

How do I make a real random number at the start of the level, or as close to it as possible? I'm looking to make a 1/4 chance of rain starting every time you start a level but of course Duke's random number generator gives the same results at start up. I've also tried using the system clock but I can't seem to get a good result. Any ideas?

[CruX]

James, on 04 November 2011 - 02:13 AM, said:

How do I make a real random number at the start of the level, or as close to it as possible? I'm looking to make a 1/4 chance of rain starting every time you start a level but of course Duke's random number generator gives the same results at start up. I've also tried using the system clock but I can't seem to get a good result. Any ideas?

Well, one rather jerry-rigged way I just threw together is to make your own 'counter' type of variable that you add onto in EVENT_GAME, then randomize the variable that would determine the chance of rain when that counter gets to a particular value.

gamevar timer 0 0
gamevar RANDOMSKYVAR -1 0 // initialize this to -1 so it won't be constantly randomized in EVENT_GAME. Also I was experimenting by changing sky textures, though I was checking the number with a digitalnumberz command...

onevent EVENT_GAME

ifvarl timer 7500 {
addvar timer 1 } else { setvar timer 7500 } // add onto the 'timer' var till it's at 7500 (roughly the first five seconds of gameplay)

ifvare timer 7500 { 
ifvarn RANDOMSKYVAR -1 break else { randvar RANDOMSKYVAR 3 } } // randomize the variable when the 'timer' var's at 7500 ONLY if it's -1....

endevent

onevent EVENT_RESETPLAYER
setvar timer 0
setvar RANDOMSKYVAR -1
endevent

Like I said, it's kinda shotty, not thoroughly tested, and I'm imagining the variables used would have to be totally unique from everything else, but it produces a different number on a pretty static basis relatively close to the loadup time.

[rasmus thorup]

randvar gamevar 3. This creates a random number from 0 to 3 which is 4 numbers. Now you can use what emericaskator told you at the start of the level, or you can use this. http://wiki.eduke32....wiki/Player_par

And 7500 is not 5 seconds. That's 250 seconds if theres 30 addvar timer 1 pr sec. Or are you doing something i don't understand?

[Danukem]

I'm not going to explain what is wrong with the last two replies, but I have a solution. I had this problem with Attrition, where the monsters were supposed to be randomized at level start, but they always turned out the same on the first level due to the random number seed starting the same every time.

gamevar randomstart 7 0
gamevar DONE 0 0

onevent EVENT_LOADACTOR

ifvare DONE NO
{
     readgamevar randomstart
     addvar randomstart 1
     andvar randomstart 65535
     setvarvar temp randomstart
     xorvar temp 43690
     whilevarn temp 0
     {
     ifrnd 1 { }
     subvar temp 1
     }
     savegamevar randomstart
     setvar DONE YES
}
endevent

The idea is you save your own number that changes each time someone starts a game, and that number effects the randomizer. I also put other stuff in the if DONE==0 block of code, basically anything that needs to happen exactly once before the map loads.

While randomstart will change each time, I think there will still be a pattern it follows, unless you set DONE back to 0 at some point after map load and then have that code run with each level load (which is what I do). Another thing you can do is, when you read randomize, if it is 0 (meaning you are running with fresh cfg files) then set it to the clock time. Reading a gamevar that is not in the cfg sets it to 0, so actually there was no point in initializing randomstart to 7...but the code still works.

[CruX]

rasmus thorup, on 04 November 2011 - 07:12 AM, said:

Now you can use what emericaskator told you at the start of the level, or you can use this. http://wiki.eduke32....wiki/Player_par
And 7500 is not 5 seconds. That's 250 seconds if theres 30 addvar timer 1 pr sec. Or are you doing something i don't understand?

It would be 250 seconds if it was being counted in tics, but it's not. EVENT_GAME is run per tic, but the 'timer' variable is being added at a faster rate, such that 7500 = 4-5 seconds. The entire reason the timer is needed is because a variable can't be randomized at the EXACT start of the level; you'll get the same number every time (use randvar in something like EVENT_RESETPLAYER, then check that variable with digitalnumberz and you'll see what I mean...)

[rasmus thorup]

aw. i just tried it. That's pretty sad. I need to go through all my codes -.- It's probably just something with the ingame watch, and i don't think i have made a randvar command yet at a decided time.

[High Treason]

Why did I stary playing with CON code again? What I am trying to do is move the game camera to a fixed location, I would like to make something that behaved like the demo cameras, but I'm clueless on that for now, so all I'm trying to do is make a single fixed camera work. I used digitalnumberz to see if the location was being set, but I can't seem to make the camera move to that position, this is what I wrote, obviously it's wrong. I'm wondering if anyone knows the variables I am supposed to set?

actor FIXIECAM // Tile 555 for now, I'll move it later
ifcanseetarget
 {
	getactor[THISACTOR].ang CAMA
	getactor[THISACTOR].x CAMX
	getactor[THISACTOR].y CAMY
	getactor[THISACTOR].z CAMZ
 }
 enda

onevent EVENT_DISPLAYREST
setvarvar camerax CAMX
setvarvar cameray CAMY
setvarvar cameraz CAMZ
setvarvar cameraang CAMA
// digitalnumber 2930 64 6 CAMA 0 0 16 windowx1 windowy1 windowx2 windowy2
// digitalnumber 2930 64 16 CAMX 0 0 16 windowx1 windowy1 windowx2 windowy2
// digitalnumber 2930 64 26 CAMY 0 0 16 windowx1 windowy1 windowx2 windowy2
// digitalnumber 2930 64 36 CAMZ 0 0 16 windowx1 windowy1 windowx2 windowy2
//  32768
endevent