[Fox]

Which gamevar flag should I use if I want it to reset when loading a map.

http://wiki.eduke32.com/wiki/Gamevar
And if someone can give a pretty more detailed explaination of what everything there means... =/

[Danukem]

Ilovefoxes, on Aug 21 2009, 09:56 PM, said:

Which gamevar flag should I use if I want it to reset when loading a map.

http://wiki.eduke32.com/wiki/Gamevar
And if someone can give a pretty more detailed explaination of what everything there means... =/

There is no flag for that, just reset it manually at the appropriate time (in EVENT_ENTERLEVEL or whatever).

[lycanox]

DeeperThought, on Aug 21 2009, 11:51 PM, said:

Two major flaws. You have { } around a single command (which is pointless), and it looks like they are supposed to go around a larger block of code.

Actually I have a lot more code it must execute at that point in the game. But I deleted it temporally to see if they were causing the problem.

Mblackwell, on Aug 22 2009, 12:41 AM, said:

I wonder why you wouldn't just define a move command and use that: eg

move MYMOVEUP 0 -100

useractor notenemy MYACTOR 
	move MYMOVEUP getv
enda

That would mean that the actor has a large chance of colliding with other actors spawned on that location.
With using the setactor[THISACTOR].z command I allowed it to safely skip some other actors to prevent issues later on in the code.

[Mblackwell]

Whatever floats your boat.

[Chip]

I've just encountered something horrible - it appears model animations are not saved when the player is not looking at them. I know the model dissapears but I thought it would have kept a count on what animated frame it would be on if it were rendered.

I first noticed this when I saw my actor perform its random idle pose but it cut out half way through and went to its walking actions. At first I had no idea why it did that and since it only ends its animation after an actioncount of 26 and it worked fine all the other times.
Problem now is that I have a rarther longish climb animation which is heavilly based on counts synced to its actions - turn away for 2 or so seconds and then when you return my actor will be in a stupid pose and it could look as bad as seeing it half submerged in the sector's floor still trying to climb a wall.


My question is:
How do I force the model itself to be rendered when not in view assuming that its animations do indeed continue to play?

[Mblackwell]

I can't say I've had that problem... are you sure you don't have an ifcansee/ifp pfacing condition floating around somewhere?

[Chip]

My actor does not have any player relating commands so no ifcansee or pfacing stuff.
My actor is also an "useractor notenemy" so it may be another limitation to that.

[RockstarForADay]

So, I'm trying to code a new enemy from scratch. Havn't touched con files for a hell of a long time and I must be doing something stupid somewhere. My enemy does everything I want it to, except die properly. Sometimes the code works perfectly, sometimes they they carry on walking and shooting. And when it spawns the dead sprite, sometimes it spawns a number of them instead of just one.

useractor enemy CHAV CHAV_NORMAL_STRENGTH

//Basic Setup
sizeat 40 20
fall
ifonwater cstat 128 else cstat 257
ifcansee
ifai NO
{
ai CHAVWALKS
ifrnd 128
sound PRED_RECOG
}


//Shooting
ifrnd 8
ifcanseetarget
ifpdistl 9000
{
ai CHAVSHOOTS 
shoot CHAVSHOT
sound PISTOL_FIRE
}

//reset code

ifcount 48
ifrnd 16
ifai CHAVSHOOTS
ai CHAVWALKS

//attacked code
ifhitweapon
{
spawn BLOOD

ifdead
{
addkills 1
ai CHAVDEAD
sound PRED_DYING
ai CHAVDEAD
spawn BLOODPOOL
}

ifrnd 8
sound PRED_PAIN
}

//death
ifai CHAVDEAD
{
ifactioncount 6
killit
spawn CHAVCORPSE
}
enda

Help a veteran n00b out, what am I doing wrong here.

[XThX2]

You have two AI CHAVDEAD's in the ifdead condition. Remove one of them. Also, add a break after the death so it doesn't try to do things after it's dead.

I have a tiny question. This code gives this error on log;

Quote

Line 6791, getactor: tried to get picnum on invalid target sprite (16384) from spr 4 pic 1405 gv spritenum2

				whilevarn spritenum2 16384
				{
					addvar spritenum2 1
					
					getactor[spritenum2].picnum picnum
					switch picnum
					case CHAINGUNNER
						canseespr THISACTOR spritenum2 returnvar7
						
						ifvare returnvar7 1
						{
							setactorvar[spritenum2].para 1
							setvar randomvar 1
							randvar randomvar 24
							mulvar randomvar 48
							setactor[spritenum2].htextra randomvar
						}
					break
					endswitch
				}

The chaingunner's picnum is 1551 and onwards. (Frames) I think it's showing the APLAYER as the result, though I do not know why. How can I fix that error ? (Note : This is in APLAYER Code, checked by a ifvarg KICKBACKPIC 85; and spritenum2 is set to 0 when kickbackpic is 84.)

[Fox]

You are trying to use getactor on every actor in the game? ID of sprites sn not as sectors, in sectors the IDs are always 1,2,3... but in the case of an actor (if I am not wrong) it can very well being 1,5,301... so if you add a counter to check every sprite, it will end up in non-existing sprites.

You should use statnum to check if the sprite exist. Statnum of 1024 belongs to non-existing sprites.

[Danukem]

I'm going to ignore the other deficiencies and just help with the specific problem you posted about. Once the actor dies, it needs to stop executing its other behavior. You were allowing the actor to switch to its other ai after dying. This can be fixed by moving the death block up near the top and adding a break, as I did below. If you examine the code in the original enemies, you will see that they do the same thing (although not exactly the same way).

useractor enemy CHAV CHAV_NORMAL_STRENGTH

//Basic Setup
sizeat 40 20
fall
ifonwater cstat 128 else cstat 257
ifcansee
ifai NO
{
ai CHAVWALKS
ifrnd 128
sound PRED_RECOG
}

//death
ifai CHAVDEAD
{
  ifactioncount 6
  {
	killit
	spawn CHAVCORPSE
  }
  break
}


//Shooting
ifrnd 8
ifcanseetarget
ifpdistl 9000
{
ai CHAVSHOOTS 
shoot CHAVSHOT
sound PISTOL_FIRE
}

//reset code

ifcount 48
ifrnd 16
ifai CHAVSHOOTS
ai CHAVWALKS

//attacked code
ifhitweapon
{
spawn BLOOD

ifdead
{
addkills 1
ai CHAVDEAD
sound PRED_DYING
ai CHAVDEAD
spawn BLOODPOOL
}

ifrnd 8
sound PRED_PAIN
}
enda

[Mblackwell]

Chip, on Aug 25 2009, 04:49 AM, said:

My actor does not have any player relating commands so no ifcansee or pfacing stuff.
My actor is also an "useractor notenemy" so it may be another limitation to that.

Care to post the relevant code?

[RockstarForADay]

Thanks XThX2 and DT! I totally forgot about a break. After moving the code up the dead spawn disapeared, so I moved the spawn back to where I originally had it and it works perfectly now.

I'm surprised there isn't much by way of tutorials regarding putting in new enemies.

Thanks again.

[Danukem]

RockstarForADay, on Aug 25 2009, 09:25 AM, said:

I'm surprised there isn't much by way of tutorials regarding putting in new enemies.

There's some useful tutorials here: http://concode.planetduke.gamespy.com/

I have thought about writing my own and adding it to the wiki, but I'm afraid it would spin out of control and take too much of my time.

[RockstarForADay]

I did see Reaper's site on my travels, but missed a few of the pages, thanks.

I think that would be an awesome edition to the wiki. Would take a while to write up though like you said. Still, the wiki could use a few more tutorials on there.

[XThX2]

				whilevarn spritenum2 16384
				{
					addvar spritenum2 1

					ifvarvarn spritenum2 THISACTOR
					{
						getactor[spritenum2].picnum picnum
						getactor[spritenum2].statnum statnum
						getactor[spritenum2].sectnum mysector
						ifvarn statnum 1024 ifvarn mysector -1
						{
							switch picnum
							case ENLISTEE case LIZTROOP case PIGCOP case LIZMAN case ZOMBIEPLS
							case OCTABRAIN case COMMANDER case DEVIL case SHADE case CHAINGUNNER
							case EXTERMINATOR case TANK case BLOODSEEKER case NEWBEAST case NNEWWBEAST
							case CDEMON case PAINE case LSOUL case APLAYER
								canseespr THISACTOR spritenum2 returnvar7
						
								ifvare returnvar7 1
								{
									setactorvar[spritenum2].para 1
									setactorvar[spritenum2].para_counter 0
									randvar randomvar 24
									mulvar randomvar 48
									setactor[spritenum2].htextra randomvar
								}
							break
							endswitch
						}
			   		}
		 		}

I've played around with the code and I'm still having the same error, with these this time ;

Quote

Line 6793, getactor: tried to get picnum on invalid target sprite (16384) from spr 0 pic 1405 gv spritenum2
Line 6794, getactor: tried to get statnum on invalid target sprite (16384) from spr 0 pic 1405 gv spritenum2
Line 6795, getactor: tried to get sectnum on invalid target sprite (16384) from spr 0 pic 1405 gv spritenum2

It gets stuck on APLAYER sprite for some reason. I don't know why. (1405 = Aplayer) What am I doing wrong here ? (Spritenum2 is -1 2)

[Danukem]

Line 6793, getactor: tried to get picnum on invalid target sprite (16384) from spr 0 pic 1405 gv spritenum2


^What that means is that sprite 0, which is a player sprite, is trying to get information from an invalid sprite (number 16384).

Put the addvar spritenum2 1 at the END of the while loop instead of the beginning.

[Fox]

Also, check the statnum before anything, you may not use getactor unless you are checking the statnum.

[XThX2]

Well checking the statnum involves getactor... Unless there's a way to do it otherwise.

Also, it is working perfectly now, thanks.

[Chip]

Mblackwell, on Aug 25 2009, 05:11 PM, said:

Care to post the relevant code?

I bring you pictures and everything!

Observe picture 1:
Everthing works fine, of course I'm facing the actor through the whole situation.
(If you click the image to gointo Imageshack, then once its loaded, click the image again to get it to a single window - then click once more to full size the image but this last part may vary depending on your web browser)



In this next test, I turn away when the climbing animation starts and then when I return its in a horrible mess!





Clearly its gone wrong all because the player turned away. I'm certain this has to be down to the whole models (well sprites and what ever they have set to them) dissapearing when out of sight and thus screwing with the animations either by pausing them or resetting them, either way my movement code carries on and forces my actor into the possitions its meant to be at but of course the animation lost sync with it and it looks silly.

Here's the climbing code:

state pokeclimbstate

ifmove MPOKEHANG1 nullop else move MPOKEHANG1 geth getv
ifvare APPLYONCE 0 { getsector[TEMP5].floorz z2 subvar z2 90 setvar APPLYONCE 1 }

getactor[THISACTOR].z z
ifvarvarl z z2 { ifcount 120 setactor[THISACTOR].xvel 32 }
else { subvar z 140 setactor[THISACTOR].z z }

ifactioncount 45 { state resetvarsstate setvar TIMEOUT 3 setvar TEMP 2 action APOKEWALK }
ends

Here's the defined animation:

   anim { frame0 "FRAME396" frame1 "FRAME480" fps 19 flags 1 }
   frame { name "FRAME396" tile 5747 } // Climb up  and over!

The actor is a "useractor notenemy", it does not have any share gamevars - all the ones it uses are per actor. There isn't a single player related command in any of its states.

[Mblackwell]

Where are you setting the initial actions? And what's resetvarstate? I only see one action call in that state. I also see an ifcount 120, which I must ask if you're ever resetting to 0. And where is TEMP5 getting set?

Oh and I reformatted your code so it's easier to read.

state pokeclimbstate

	ifmove MPOKEHANG1
		nullop
	else
		move MPOKEHANG1 geth getv

	ifvare APPLYONCE 0
	{
		getsector[TEMP5].floorz z2
		subvar z2 90
		setvar APPLYONCE 1
	}

	getactor[THISACTOR].z z
	ifvarvarl z z2
	{
		ifcount 120
			setactor[THISACTOR].xvel 32
	}
	else
	{
		subvar z 140
		setactor[THISACTOR].z z
	}

	ifactioncount 45
	{
		state resetvarsstate
		setvar TIMEOUT 3
		setvar TEMP 2
		action APOKEWALK
	}
ends

[Danukem]

This is pretty clearly a problem with some internal animation counter on the model not behaving correctly because it is not being rendered (as Chip suggested). Unless he has something really silly in his code (like ifp pfacing nullop else action...) looking away from the model and then back again isn't going to make any difference to its animation. It reminds me of an HRP issue (which I know was at least partially fixed) where dead monsters would display their death animation again if you hadn't looked at them in a while.

[Chip]

Quote

Where are you setting the initial actions? And what's resetvarstate? I only see one action call in that state. I also see an ifcount 120, which I must ask if you're ever resetting to 0. And where is TEMP5 getting set?

All actions and vars are being set from another state followed by an instant "break" (in this case it was set in its hang state which it does before climbing) TEMP5 holds the sector's ID where it plans on climbing to which was set in its jump state. Its only reset in its standard paving stuff. Resetvarsstate is a state used to set my important gamevars to 0 (In this case my jumpable vars since the otheres were untouced)
That ifcount however isn't being reset - I forgot about that so I may throw into the resetvarsstate but it shouldn't cause any problems since it will get automaticaly reset in its seekstate upon the first invalid spotted sector. (It has an ifcount 2 { resetcount ......stuff... } when it doesn't like the look of the upcoming sector) My actor doesn't do anything else with that count so its harmless at the moment.

Quote

Oh and I reformatted your code so it's easier to read.

That's how I used to always write out my code but I actually started finding it easier to read in the other way, Its especially quicker to skim past.

Quote

It reminds me of an HRP issue (which I know was at least partially fixed) where dead monsters would display their death animation again if you hadn't looked at them in a while.

I guess that's a little more evidence that models and animations needs a little looking into. For me this bug of re-animating dead monsters always occurs when I reload a saved gamed.

[Danukem]

The only thing I can think of that might help is setting mdflags to 16 on the actors. It can't hurt to try.

http://wiki.eduke32.com/wiki/Mdflags

[Chip]

DeeperThought, on Aug 26 2009, 10:02 PM, said:

The only thing I can think of that might help is setting mdflags to 16 on the actors. It can't hurt to try.

http://wiki.eduke32.com/wiki/Mdflags

Yeah I tried that but it unfortunately didn't work, assuming I used it right. (which I may have not now that I think about it). I will however also try changing my actor from notenemy to enemy to see if that makes any change since enemies do alot more stuff then notenemies (I've only recently found out the enemy tagged actors have a built in paving code to help it avoid walls - not a good one but there is indeed one in there. I guess that's why it jerks in movement.)

[XThX2]

Is canseespr only working if both actors are in the same sector ? Or at close/same heights ? Because, in my case with the code I've posted before (with the fixes you guys suggested) it never works when I go to a different sector than the actor that I'm supposed to be seeing, or when I go to a higher place like ramps, or cliffs.

[Chip]

I'm certain I've seen it working over sectors since I distinctly remember seeing one of my Marines (from my old badly coded Doom mod) shooting over a table to hit an Imp. But I can't test it now so I can't proove anything.

If you're still having problems then you could aways try cansee which indeed can cross sectors (else it would be pointless for the command to need sector IDs imputted for botth points) but with that you'll need to obtain more details before using the command.

Side note, cansee is fantastic for paving code!

[XThX2]

Strange, cansee works just perfectly, whereas canseespr fails to work over height/sector changes. Cansee also seems more useful because of the information it uses.

[Danukem]

XThX2, on Aug 27 2009, 07:49 AM, said:

Strange, cansee works just perfectly, whereas canseespr fails to work over height/sector changes. Cansee also seems more useful because of the information it uses.

I'm guessing that when you used cansee, you set the z coordinates appropriately. canseespr works fine too, but keep in mind that sprites see from the bottoms of their feet, so it's a good idea to lift them up before using it.

[m210®]

It is possible to operate SE12 by means of a code?