[Danukem]

Perro Seco, on 14 October 2017 - 02:01 PM, said:

I managed to hide the weapon sprites, but how can I make the player visible? I thought I would have to do something with its cstat, but using DNDEBUG I see is 257. If you can give me a hint I would be very grateful.

You could try forcing over_shoulder_on to 1. Normally this would also change the camera position, but since you are already forcing a camera position as well, it might do the job. Don't forget to restore it to the previous value when camera viewing ends. EDIT: To be clear, this isn't necessary the best solution, but I don't remember what is going on with the player sprite that makes it invisible. It might be a tsprite thing.

[thisbecasper]

Now i've tried a couple of things in order to achieve an rpg projectile that bounces.

//First try
defineprojectile 1660 PROJ_WORKSLIKE 32774
defineprojectile 1660 PROJ_SPAWNS EXPLOSION2
defineprojectile 1660 PROJ_VEL 1000
defineprojectile 1660 PROJ_EXTRA 300
defineprojectile 1660 PROJ_ISOUND PIPEBOMB_EXPLODE
defineprojectile 1660 PROJ_HITRADIUS 2560
defineprojectile 1660 PROJ_BOUNCES 5
defineprojectile 1660 PROJ_OFFSET 14354
defineprojectile 1660 PROJ_CLIPDIST 24
defineprojectile 1660 PROJ_TRAIL SMALLSMOKE


//Second try
//setprojectile[2605].bounces 32774
//setprojectile[2605].workslike

ofc it wont work because im missing something, but i dont see where. In the DEFS.CON ive changed "define RPG 2605" to "define RPG 1660" for the first try.

bump :')

[Danukem]

thisbecasper, on 14 October 2017 - 11:35 PM, said:

In the DEFS.CON ive changed "define RPG 2605" to "define RPG 1660" for the first try.

Yeah don't do that. Leave the hardcoded RPG alone and make yours into a separate tile number. Make sure you have art on the tile you are using, too.

[thisbecasper]

Trooper Dan, on 15 October 2017 - 10:18 AM, said:

Yeah don't do that. Leave the hardcoded RPG alone and make yours into a separate tile number. Make sure you have art on the tile you are using, too.

How does the weapon (which weapon??) know what projectile to shoot? If I wanted to make the rpg shoot rockets that bounce, how do i do it? I tried it without the change in the DEFS with no luck

[Danukem]

thisbecasper, on 15 October 2017 - 10:36 AM, said:

How does the weapon (which weapon??) know what projectile to shoot? If I wanted to make the rpg shoot rockets that bounce, how do i do it? I tried it without the change in the DEFS with no luck

You can re-declare the gamevar that controls which projectile the weapon fires:

gamevar WEAPON4_SHOOTS 1660 1

http://wiki.eduke32....efined_gamevars

[thisbecasper]

Trooper Dan, on 15 October 2017 - 03:13 PM, said:

You can re-declare the gamevar that controls which projectile the weapon fires:

gamevar WEAPON4_SHOOTS 1660 1

http://wiki.eduke32....efined_gamevars

Thanks! That made me achieve ton of stuff already!
I can't get my burst project to work tho. What I want for now is just a weapon that, with a single tap on the shooting button, shoots a burst of lets say 4 shots in succession and then stops briefly inbetween bursts. I hope to get some clarification on the kickback_pic and totaltime and so. I've read the wikis but i'm missing something... Also: It seems that with this "gamevar WEAPON3_FLAGS xx" that im only adding stuff to the weapon. How do I delete the "WEAPON_RESET" on WEAPON3?

Thanks again for the help!

Last thing: Where are the weapons function defined in the first place? Not in the conf file? I've searched for RPG, WEAPON4, and flags and such, no succes..

[Hendricks266]

thisbecasper, on 15 October 2017 - 05:12 PM, said:

What I want for now is just a weapon that, with a single tap on the shooting button, shoots a burst of lets say 4 shots in succession and then stops briefly inbetween bursts.

You'll want to set WEAPON3_SHOTSPERBURST to 4, and probably add AMMOPERSHOT to WEAPON3_FLAGS.

thisbecasper, on 15 October 2017 - 05:12 PM, said:

Also: It seems that with this "gamevar WEAPON3_FLAGS xx" that im only adding stuff to the weapon. How do I delete the "WEAPON_RESET" on WEAPON3?

Declaring the gamevar in your con files will erase the ones already there and only set the flags you name.

thisbecasper, on 15 October 2017 - 05:12 PM, said:

Last thing: Where are the weapons function defined in the first place? Not in the conf file? I've searched for RPG, WEAPON4, and flags and such, no succes..

They're hardcoded into the exe.

[thisbecasper]

Hendricks266, on 15 October 2017 - 07:04 PM, said:

You'll want to set WEAPON3_SHOTSPERBURST to 4, and probably add AMMOPERSHOT to WEAPON3_FLAGS.


Declaring the gamevar in your con files will erase the ones already there and only set the flags you name.


They're hardcoded into the exe.

Thank you once again for the clarification!

[thisbecasper]

Hmm, how do I alter the speed which the pipebomb is thrown at? I think this could be tricky to work with because there has to be a lot of hardcoding involved in those pipes I want to be able to throw the pipebomb ridicously far
And how do I add a new weapon? Like for example the expander that exchanges the shrinker when you switch to shrinker once again. I would like a secondary shotgun..

[thisbecasper]

Is it possible to make the shotgun for example shoot normally when pressing the fire button, but shoot, lets say rockets, when turnaround is pressed instead?

[Hendricks266]

Untested, but let me know how this goes.

onevent EVENT_TURNAROUND
    setvar WEAPON2_SHOOTS RPG
    setplayer[THISACTOR].kickback_pic 1

    setvar RETURN -1
endevent

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
endevent

[thisbecasper]

Hendricks266, on 16 October 2017 - 02:55 PM, said:

Untested, but let me know how this goes.

onevent EVENT_TURNAROUND
    setvar WEAPON2_SHOOTS RPG
    setplayer[THISACTOR].kickback_pic 1

    setvar RETURN -1
endevent

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
endevent

This actually works, although it shoots 7 rockets on top of eachother. This is just a matter of redefining a couple of more things in the first bit of the code I guess. It does only fire in rpg-mode a single time when holding down the fire button, BUT, if you tap the turnaround you can spam the rockets heheh. Thank you for the reply, I learn quite a bit reading code like this :-) Maybe I can continue working on the code myself too..

[Hendricks266]

Hmm

onevent EVENT_TURNAROUND
    setvar WEAPON2_SHOOTS RPG
    ifvare player[].kickback_pic 0
        setplayer[].kickback_pic 1

    setvar RETURN -1
endevent

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
endevent

[thisbecasper]

Hendricks266, on 16 October 2017 - 07:01 PM, said:

Hmm

onevent EVENT_TURNAROUND
    setvar WEAPON2_SHOOTS RPG
    ifvare player[].kickback_pic 0
        setplayer[].kickback_pic 1

    setvar RETURN -1
endevent

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
endevent

"GAME.CON: In event `EVENT_TURNAROUND':
GAME.CON:215: error: symbol `player' is not a game array.
GAME.CON:215: error: parameter `.kickback_pic' is undefined.
GAME.CON:215: error: expected a keyword but found `0'.
GAME.CON:216: error: symbol `kickback_pic' is not a game variable.
GAME.CON:216: error: syntax error."

[Hendricks266]

How old of an EDuke32 are you using?

[thisbecasper]

Hendricks266, on 16 October 2017 - 07:30 PM, said:

How old of an EDuke32 are you using?

EDuke32-OldMP (Maintenance Build) Release 9 20120912
- And that's what's causing it. It works on my "normal" Eduke :-) A bit annoying tho, because the stuff I'm trying to make is for multiplayer purposes only :/

[Hendricks266]

define INPUT_TURN_AROUND       268435456

gamevar temp 0 0
gamevar bits 0 1

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
    setvar WEAPON2_SHOTSPERBURST 7
endevent

onevent EVENT_TURNAROUND
    setvar RETURN -1
endevent

onevent EVENT_PROCESSINPUT
    getinput[THISACTOR].bits bits
endevent

onevent EVENT_GAME
    ifactor APLAYER
    {
        ifvarand bits INPUT_TURN_AROUND
        {
            ifvare currentweapon SHOTGUN_WEAPON
            {
                ifvare weaponcount 0
                {
                    getplayer[THISACTOR].ammo_amount SHOTGUN_WEAPON temp
                    ifvarg temp 0
                    {
                        setvar WEAPON2_SHOOTS RPG
                        setvar WEAPON2_SHOTSPERBURST 1

                        setplayer[THISACTOR].kickback_pic 1
                    }
                }
            }
        }
    }
endevent

[thisbecasper]

Hendricks266, on 16 October 2017 - 07:45 PM, said:

define INPUT_TURN_AROUND       268435456

gamevar temp 0 0
gamevar bits 0 1

onevent EVENT_PRESSEDFIRE
    setvar WEAPON2_SHOOTS SHOTGUN
    setvar WEAPON2_SHOTSPERBURST 7
endevent

onevent EVENT_TURNAROUND
    setvar RETURN -1
endevent

onevent EVENT_PROCESSINPUT
    getinput[THISACTOR].bits bits
endevent

onevent EVENT_GAME
    ifactor APLAYER
    {
        ifvarand bits INPUT_TURN_AROUND
        {
            ifvare currentweapon SHOTGUN_WEAPON
            {
                ifvare weaponcount 0
                {
                    getplayer[THISACTOR].ammo_amount SHOTGUN_WEAPON temp
                    ifvarg temp 0
                    {
                        setvar WEAPON2_SHOOTS RPG
                        setvar WEAPON2_SHOTSPERBURST 1

                        setplayer[THISACTOR].kickback_pic 1
                    }
                }
            }
        }
    }
endevent

Damn... Thank you so much! Works like a charm.. It even acts exactly as it should now. I just need to know why I need to do this step:

"onevent EVENT_TURNAROUND
setvar RETURN -1
endevent"

- And I guess gamevar bits is used to remember last keypress, if im right?

[Hendricks266]

Setting RETURN to -1 in EVENT_TURNAROUND disables the Turn Around action from taking place.

The bits gamevar is updated with the current state of the keys at all times.

[thisbecasper]

Hendricks266, on 16 October 2017 - 08:05 PM, said:

Setting RETURN to -1 in EVENT_TURNAROUND disables the Turn Around action from taking place.

The bits gamevar is updated with the current state of the keys at all times.

Yep! Just found out myself. I actually made a toggle instead.

define INPUT_TURN_AROUND       268435456

gamevar choice 0 1

onevent EVENT_TURNAROUND
    setvar RETURN -1
endevent

onevent EVENT_TURNAROUND
    ifvare currentweapon SHOTGUN_WEAPON
    {
    	ifvare choice 0
    	{
    		setvar choice 1
    	}
    	else
    	{
    		setvar choice 0
    	} 
    	}
endevent

onevent EVENT_PRESSEDFIRE
	ifvare choice 0
	{
		setvar WEAPON2_SHOOTS SHOTGUN
    	setvar WEAPON2_SHOTSPERBURST 7
	}
	else
	{
		setvar WEAPON2_SHOOTS RPG
        setvar WEAPON2_SHOTSPERBURST 1
	}	    
endevent

Although it doesn't work when I add the RETURN -1 bit. I guess it wont let the next onevent EVENT_TURNAROUND get executed. I think I would have to use the "bits" var like you did! But thanks for the help!

[Danukem]

thisbecasper, on 16 October 2017 - 08:21 PM, said:

Although it doesn't work when I add the RETURN -1 bit.

It should work. You don't need two different declarations of the same event; I wonder if that's related.

thisbecasper, on 16 October 2017 - 08:21 PM, said:

I guess it wont let the next onevent EVENT_TURNAROUND get executed.

The value of RETURN is not saved; it is constantly getting set to different values by various events and such.

[thisbecasper]

Trooper Dan, on 16 October 2017 - 11:39 PM, said:

It should work. You don't need two different declarations of the same event; I wonder if that's related.

Thanks! That was what caused it.

[thisbecasper]

Hi, just tried it with my friend, and we get an out-of-sync when one of us dies. Heres the code, I hope I can make a getaround:

define INPUT_TURN_AROUND       268435456

gamevar SHOTGUNAMMO 0 1
gamevar choice 0 1

onevent EVENT_TURNAROUND
{
	setvar RETURN -1
    ifvare choice 0
    {
  		setvar choice 1
  		sound SELECT_WEAPON        
      quote 34
    }
    else
  	{
  		setvar choice 0
    		sound SHOTGUN_COCK
        quote 35
    	} 
    }    
endevent

onevent EVENT_PRESSEDFIRE
{	 
	ifvare choice 0
	{
		setvar WEAPON2_SHOOTS SHOTGUN
  	setvar WEAPON2_SHOTSPERBURST 7
    setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
    setvar WEAPON2_FLAGS 1024
	}
	else
	{
		ifvarl SHOTGUNAMMO 10
		{
			setvar choice 0
			quote 40
			sound SHOTGUN_COCK

		}
		setvar WEAPON2_SHOOTS 1092
    setvar WEAPON2_SHOTSPERBURST 10
    setvar WEAPON2_FIRESOUND PISTOL_RICOCHET
   	setvar WEAPON2_FLAGS 17472 				
	}
}

endevent

Also the sound won't update accordingly between "weapon-switch".

[Hendricks266]

If you're using a switch style, you should update the vars directly in EVENT_TURNAROUND instead of using PRESSEDFIRE.

What is that SHOTGUNAMMO variable? I suspect you don't need it.

[thisbecasper]

Hendricks266, on 17 October 2017 - 08:09 AM, said:

If you're using a switch style, you should update the vars directly in EVENT_TURNAROUND instead of using PRESSEDFIRE.

What is that SHOTGUNAMMO variable? I suspect you don't need it.

Thank you for the help. I've got it to work now like this:

gamevar SHOTGUNAMMO 0 1
gamevar choice 0 1
gamevar PWEAPON 0 1

onevent EVENT_TURNAROUND
{
	setvar RETURN -1
	ifvare PWEAPON 2
   	{
    	ifvare choice 0
    	{
    		ifvarl SHOTGUNAMMO 10
    		{
    			quote 36
    			break
    		}
    		setvar choice 1
    		sound SELECT_WEAPON
    		setvar WEAPON2_SHOOTS 1092
       		setvar WEAPON2_SHOTSPERBURST 10
       		setvar WEAPON2_FIRESOUND PISTOL_RICOCHET
       		setvar WEAPON2_FLAGS 17472 	
        	quote 34
    	}
    	else
    	{
    		setvar choice 0
    		sound SHOTGUN_COCK
    		setvar WEAPON2_SHOOTS SHOTGUN
    		setvar WEAPON2_SHOTSPERBURST 7
    		setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
    		setvar WEAPON2_FLAGS 1024
        	quote 35
    	} 
    }
}	    
endevent

onevent EVENT_DOFIRE
{
	ifvare PWEAPON 2
	{
		ifvare choice 1
		{
			ifvarl SHOTGUNAMMO 10
			{
				setvar choice 0
    			sound SHOTGUN_COCK
    			setvar WEAPON2_SHOOTS SHOTGUN
    			setvar WEAPON2_SHOTSPERBURST 7
    			setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
    			setvar WEAPON2_FLAGS 1024
        		quote 40
			}
		}
	}
}
endevent

I think I need the var SHOTGUNAMMO inorder to keep track of current ammo of the shotgun?. Can I do it without the var and without causing an out-of-sync error? I've btw also managed to get rid of the out-of-sync thing - I still don't see the big difference between using a var like I do to keep track of the players current weapon and a call to currentweapon, which was what caused it..

[Danukem]

thisbecasper, on 17 October 2017 - 12:05 PM, said:

I think I need the var SHOTGUNAMMO inorder to keep track of current ammo of the shotgun?

Where you have

ifvarl SHOTGUNAMMO 10

you should be able to replace it with

ifvarl player[THISACTOR].ammo_amount 2 10

[Hendricks266]

thisbecasper, on 17 October 2017 - 12:05 PM, said:

I think I need the var SHOTGUNAMMO inorder to keep track of current ammo of the shotgun?. Can I do it without the var and without causing an out-of-sync error? I've btw also managed to get rid of the out-of-sync thing - I still don't see the big difference between using a var like I do to keep track of the players current weapon and a call to currentweapon, which was what caused it..

The game already keeps track of things like ammo counts and current weapon. Attempting to circumvent this by using your own vars at best is a duplication of effort, and at worst is asking for a lot of trouble when you let them get out of sync.

Yeah, currentweapon was a mistake, it should only be used in HUD drawing events.

You're going to need to get comfortable with global scratch variables. While you're at it, take the time to indent your code correctly. (8 spaces per tab stop is unnecessary, use 4 at the max.)

definegamefuncname 36 Switch_Weapon_Function

gamevar temp 0 0

gamevar subweapon_choice 0 1

onevent EVENT_TURNAROUND
    setvar RETURN -1

    getplayer[THISACTOR].curr_weapon temp
    ifvare temp 2
    {
        ifvare subweapon_choice 0
        {
            ifvarl SHOTGUNAMMO 10
            {
                quote 36
                break
            }
            setvar subweapon_choice 1
            sound SELECT_WEAPON
            setvar WEAPON2_SHOOTS 1092
            setvar WEAPON2_SHOTSPERBURST 10
            setvar WEAPON2_FIRESOUND PISTOL_RICOCHET
            setvar WEAPON2_FLAGS 17472
            quote 34
        }
        else
        {
            setvar subweapon_choice 0
            sound SHOTGUN_COCK
            setvar WEAPON2_SHOOTS SHOTGUN
            setvar WEAPON2_SHOTSPERBURST 7
            setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
            setvar WEAPON2_FLAGS 1024
            quote 35
        }
    }
endevent

onevent EVENT_DOFIRE
    getplayer[THISACTOR].curr_weapon temp
    ifvare temp 2
    {
        ifvare subweapon_choice 1
        {
            getplayer[THISACTOR].ammo_amount SHOTGUN_WEAPON temp
            ifvarl temp 10
            {
                setvar subweapon_choice 0
                sound SHOTGUN_COCK
                setvar WEAPON2_SHOOTS SHOTGUN
                setvar WEAPON2_SHOTSPERBURST 7
                setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
                setvar WEAPON2_FLAGS 1024
                quote 40
            }
        }
    }
endevent

Trooper Dan, on 17 October 2017 - 12:11 PM, said:

Where you have

ifvarl SHOTGUNAMMO 10

you should be able to replace it with

ifvarl player[THISACTOR].ammo_amount 2 10

He's using OldMP, which doesn't support quick structure access. Also, use SHOTGUN_WEAPON instead of the magic constant '2'.

[Danukem]

Hendricks266, on 17 October 2017 - 12:15 PM, said:

Also, use SHOTGUN_WEAPON instead of the magic constant '2'.

Now you are just being pedantic. There's no advantage to typing the label there except for readability, but anyone who has worked with the game very long knows which weapons the numbers correspond to.

[Hendricks266]

Trooper Dan, on 17 October 2017 - 12:31 PM, said:

Now you are just being pedantic. There's no advantage to typing the label there except for readability, but anyone who has worked with the game very long knows which weapons the numbers correspond to.

You're basically telling me "Who cares?", which is a pet peeve when I'm trying to get across something important. Your argument is a slippery slope to completely neglecting your code style, after all, you know what it does.

This stands opposed to every commit Helix or I have made regarding "enumifying" a set of magic constants.

Furthermore, what if you want to search for all code effecting the shotgun at once? The Unix utility for this is called grep, and you'll usually see it used as a verb. You'll have much more luck grepping for SHOTGUN_WEAPON than "2".

[thisbecasper]

Hendricks266, on 17 October 2017 - 12:15 PM, said:

The game already keeps track of things like ammo counts and current weapon. Attempting to circumvent this by using your own vars at best is a duplication of effort, and at worst is asking for a lot of trouble when you let them get out of sync.

Yeah, currentweapon was a mistake, it should only be used in HUD drawing events.

You're going to need to get comfortable with global scratch variables. While you're at it, take the time to indent your code correctly. (8 spaces per tab stop is unnecessary, use 4 at the max.)

definegamefuncname 36 Switch_Weapon_Function

gamevar temp 0 0

gamevar subweapon_choice 0 1

onevent EVENT_TURNAROUND
    setvar RETURN -1

    getplayer[THISACTOR].curr_weapon temp
    ifvare temp 2
    {
        ifvare subweapon_choice 0
        {
            ifvarl SHOTGUNAMMO 10
            {
                quote 36
                break
            }
            setvar subweapon_choice 1
            sound SELECT_WEAPON
            setvar WEAPON2_SHOOTS 1092
            setvar WEAPON2_SHOTSPERBURST 10
            setvar WEAPON2_FIRESOUND PISTOL_RICOCHET
            setvar WEAPON2_FLAGS 17472
            quote 34
        }
        else
        {
            setvar subweapon_choice 0
            sound SHOTGUN_COCK
            setvar WEAPON2_SHOOTS SHOTGUN
            setvar WEAPON2_SHOTSPERBURST 7
            setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
            setvar WEAPON2_FLAGS 1024
            quote 35
        }
    }
endevent

onevent EVENT_DOFIRE
    getplayer[THISACTOR].curr_weapon temp
    ifvare temp 2
    {
        ifvare subweapon_choice 1
        {
            getplayer[THISACTOR].ammo_amount SHOTGUN_WEAPON temp
            ifvarl temp 10
            {
                setvar subweapon_choice 0
                sound SHOTGUN_COCK
                setvar WEAPON2_SHOOTS SHOTGUN
                setvar WEAPON2_SHOTSPERBURST 7
                setvar WEAPON2_FIRESOUND SHOTGUN_FIRE
                setvar WEAPON2_FLAGS 1024
                quote 40
            }
        }
    }
endevent

He's using OldMP, which doesn't support quick structure access. Also, use SHOTGUN_WEAPON instead of the magic constant '2'.

It makes sense that you can do it like this, without declaring a new var. Regarding indentation: Yeah, it happens when I copy paste into duke4net, it's good in sublime text
If I don't use my SHOTGUNAMMO like I coded, and instead like in your code, It doesn't work - It's like it doesn't register the current ammo at all, maybe I'm missing some declaration?
- Is there a way to change the color of the crosshair together with weapon-switches?? Can't seem to find anything about it online.